Wolfram 语言与系统参考资料中心

Ball

参见
- 函数
- Disk
- Sphere
- Ellipsoid
- Circumsphere
- Cylinder
- Cone
- ImplicitRegion
- BoundingRegion
- 格式
- PLY
- X3D
相关指南
- 参见
  - 函数
  - Disk
  - Sphere
  - Ellipsoid
  - Circumsphere
  - Cylinder
  - Cone
  - ImplicitRegion
  - BoundingRegion
  - 格式
  - PLY
  - X3D
- 相关指南

Ball

Ball[p]

表示中心在点 p 的单位球.

Ball[p,r]

表示中心在点 p、半径为 r 的球.

Ball[{p₁,p₂,…},r]

表示半径为 r 的一组球.

背景

Ball 是一个图形和几何基元，表示一个在维空间的球. 尤其是，Ball[p,r] 表示一个在 $TemplateBox[{}, Reals]^n$ 中的（填充的）球，其中心为 p，半径为 r，r 可以是任何非负实数，p 可以有任何正长度 . 速记形式 Ball[p] 等同于 Ball[p,1]，Ball[n] 等同于 Ball[ConstantArray[0, n],1]，其中 Ball[] 自动计算为 Ball[{0,0,0}].
共同半径的球对象（多个球）收集可以使用 Ball[{p₁,…,p_k},r] 高效表示，有多种半径的球可以用 Ball[{p₁,…,p_k},{r₁,…,r_k}] 表示.
Ball 对象可以分别使用 Graphics 和 Graphics3D 在二维和三维中进行可视格式化. 图形中的 Ball 对象外观的修改可以通过指定边指令 EdgeForm (2D) 或面指令 FaceForm (3D)，颜色指令例如，Red，透明度和镜面反射度 Opacity 和 Specularity，样式选项 Antialiasing.
Ball 也可以作为在其上执行计算的区域规范. 例如，Integrate[1,{x,y,z}∈Ball[{0,0,0},r]] 和 Volume[Ball[{0,0,0},r]] 均返回半径为的 3D 球的体积 .
Ball 还与其他符号相关. Sphere 表示球的边界，可以用 RegionBoundary[Ball[{x,y,z},r]] 计算. Ball 是 Interval 和 Disk 到任意维数的推广，Ellipsoid 是 Ball 的推广，在某种意义上，对于所有，Ball[{p₁,…,p_k},1] 等同于 Ellipsoid[{p₁,…,p_k},ConstantArray[1,k]]. SphericalShell 给出了从较大的同心球的内部去除一个小球而获得的填充的壳. 3D 中的 Ball 对象可以表示为 ImplicitRegion[(x-u)²+(y-v)²+(z-w)²≤r²,{u,v,w}] 或 ParametricRegion[a{Cos[θ]Sin[ϕ],Sin[θ]Sin[ϕ],Cos[ϕ]}-{x,y,z},{{θ,0,2π},{ϕ,0,π},{a,0,r}}]. 3D 球的预计算属性和其在标准位置上的变体可使用 SolidData["entity", "property"] 或 EntityValue[Entity["Ball","entity"],"property"]，其中"entity" 是 "Ball" 或 "HalfBall" 中的一个.

范例

打开所有单元关闭所有单元

基本范例 (2)

在三维中的单位球：

Wolfram Language code: Graphics3D[Ball[]]

在二维中：

Wolfram Language code: Graphics[Ball[2]]

体积和质心：

Wolfram Language code: Volume[Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r]]

Wolfram Language code: RegionCentroid[Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r]]

范围 (22)

图形 (12)

指定 (4)

默认值是三维中原点处的一个单位球：

Wolfram Language code: Graphics3D[Ball[]]

不同维度的单位球：

Wolfram Language code: Graphics[Ball[2]]

Wolfram Language code: Graphics3D[Ball[3]]

不同位置和半径的球：

Wolfram Language code: Graphics3D[{Ball[{-1, -1, -1}], Ball[{1, 2, 3}, 2]}]

相等半径的多个球：

Wolfram Language code: Graphics3D[Ball[{{0, 0, 0}, {1, 1, 1}}, 1 / 2]]

样式化 (4)

具有不同镜面指数的球：

Wolfram Language code: Table[Graphics3D[{Orange, Specularity[White, n], Ball[]}], {n, {5, 20, 100}}]

发红光的黑球：

Wolfram Language code: Graphics3D[{Glow[Red], Black, Ball[]}]

Opacity 指定面的不透明度：

Wolfram Language code: Table[Graphics3D[{Opacity[o], Ball[]}], {o, {0.3, 0.5, 0.9}}]

二维样式化：

Wolfram Language code: Graphics[{EdgeForm[{Thick, Dashed, Blue}], Brown, Ball[2]}]

坐标 (4)

以绘图范围分数的形式指定坐标：

Wolfram Language code: Graphics[Ball[Scaled[{0.5, 0.75}], 1], PlotRange -> {{0, 4}, {0, 4}}, Frame -> True]

Wolfram Language code: Graphics3D[Ball[Scaled[{0.5, 0.5, 0.75}], 1], PlotRange -> {{0, 4}, {0, 4}, {0, 4}}, Axes -> True]

以绘图范围分数的形式指定半径：

Wolfram Language code: Graphics[Ball[{2, 2}, Scaled[0.25]], Frame -> True]

Wolfram Language code: Graphics3D[Ball[{0, 0, 0}, Scaled[0.25]], Axes -> True]

指定从普通坐标缩放的偏移量：

Wolfram Language code: Graphics[Ball[ Scaled[{0.5, 0.25}, {1, 1}], 0.5], Frame -> True]

Wolfram Language code: Graphics3D[Ball[Scaled[{0, 0, 0.5}, {1, 1, 1}]], PlotRange -> {{0, 4}, {0, 4}, {0, 4}}, Axes -> True]

点可以是 Dynamic：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {-0.5, 0.5}], Graphics3D[{Ball[], Ball[{Dynamic[x], 1, 1}, 0.3]}]}]

区域 (10)

嵌入维是球所在空间的维度：

Wolfram Language code: RegionEmbeddingDimension[Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r]]

几何维度是形状本身的尺寸：

Wolfram Language code: RegionDimension[Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r]]

成员测试：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];

Wolfram Language code: {RegionMember[ℛ, {(1/3), (1/3), (1/3)}], RegionMember[ℛ, {1, 1, 1}]}

得到点成员的条件：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

体积：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];

Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]

Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}]

到一个点的距离：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];

Wolfram Language code: {RegionDistance[ℛ, {(1/3), (1/4), (1/5)}], RegionDistance[ℛ, {1, 1, 1}]}

到二维球最近点的距离：

Wolfram Language code: Plot3D[RegionDistance[Ball[{0, 0}, 1], {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> 5]

三维球的等距轮廓：

Wolfram Language code:

ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -2, 2}, {y, 0, 2}, {z, -2, 2}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

到一个点的带有正符号的距离：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];

Wolfram Language code: {SignedRegionDistance[ℛ, {1, 1, 1}], SignedRegionDistance[ℛ, {1 / 2, 1 / 2, 1 / 2}]}

到二维球的带有正符号的距离：

Wolfram Language code:

Plot3D[SignedRegionDistance[Ball[{0, 0}, 1], {x, y}], {x, -2, 2}, {y, -2, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

区域上的最近点：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];

Wolfram Language code: {RegionNearest[ℛ, {1, 1, 1}], RegionNearest[ℛ, {1 / 2, 1 / 2, 1 / 2}]}

到一个封闭球体的最近点：

Wolfram Language code:

spherePoints[{n_, m_}, c_, r_] := 
	Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];

Wolfram Language code:

pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 2];
npl = Table[RegionNearest[ℛ, p], {p, pl}];

Wolfram Language code:

Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

球是有界的：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, 1];

Wolfram Language code: BoundedRegionQ[ℛ]

求它的范围：

Wolfram Language code: r = RegionBounds[ℛ]

Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

在球的区域上积分：

Wolfram Language code: ℛ = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3]}, r];

Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ]

在球的区域上最优化：

Wolfram Language code: ℛ = Ball[{1, 2, 3}, 4];

Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

求解球的区域上的方程：

Wolfram Language code: ℛ = Ball[{1, 2, 3}, 3];

Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -(1/2) && z^2 == x y + (1/4) && {x, y, z}∈ℛ, {x, y, z}]

应用 (3)

求体积为的球的最小表面积：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, r];

Wolfram Language code: Minimize[{Area[RegionBoundary[ℛ]], Volume[ℛ] == 2π && r > 0}, {r}]

球区域的总质量，其密度由给出：

Wolfram Language code: ℛ = Ball[{a, b, c}, r];

Wolfram Language code: Integrate[x y z, {x, y, z}∈ℛ, Assumptions -> r > 0 && (a | b | c)∈Reals]

求半径为3厘米的球中咖啡因的质量：

Wolfram Language code: ℛ = Ball[{0, 0, 0}, Quantity[3, "Centimeters"]];

咖啡因的密度：

Wolfram Language code: d = ChemicalData["Caffeine", "Density"]

球的体积：

Wolfram Language code: v = Volume[ℛ]

球中咖啡因的质量：

Wolfram Language code: FormulaData["MassDensity", {"ρ" -> d, "V" -> N[v]}]

属性和关系 (5)

Disk 是 Ball 的特例：

Wolfram Language code: RegionMember[Disk[{0, 0}, 1], {x, y}]

Wolfram Language code: RegionMember[Ball[{0, 0}, 1], {x, y}]

Sphere 是 Ball 的 RegionBoundary：

Wolfram Language code: RegionBoundary[Ball[{x, y, z}, r]]

Ellipsoid 是广义的 Ball：

Wolfram Language code:

Subscript[ℛ, 1] = Ellipsoid[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, {1, 1, 1, 1}];
Subscript[ℛ, 2] = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, 1];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion 可以表示任何 Ball：

Wolfram Language code:

Subscript[ℛ, 1] = ImplicitRegion[(Subscript[t, 1] - Subscript[c, 1])^2 + (Subscript[t, 2] - Subscript[c, 2])^2 + (Subscript[t, 3] - Subscript[c, 3])^2 + (Subscript[t, 4] - Subscript[c, 4])^2 ≤ 1, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3], Subscript[t, 4]}];
Subscript[ℛ, 2] = Ball[{Subscript[c, 1], Subscript[c, 2], Subscript[c, 3], Subscript[c, 4]}, 1];

Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

Ball 是欧几里德范数的范数球：

Wolfram Language code: ℛ = Ball[{0, 0, 0, 0}, 1];

Wolfram Language code:

Reduce[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}∈ℛ⧦Norm[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}] ≤ 1, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3], Subscript[x, 4]}, Reals]

巧妙范例 (1)

随机球集合：

Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Ball[RandomReal[1, {3}], RandomReal[0.1]]}, {200}]]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Ball

更多信息和选项

背景

范例

基本范例 (2)

范围 (22)

图形 (12)

指定 (4)

样式化 (4)

坐标 (4)

区域 (10)

应用 (3)

属性和关系 (5)

巧妙范例 (1)

文本

CMS

APA

BibTeX

BibLaTeX

Ball

更多信息和选项

背景

范例

基本范例 (2)

范围 (22)

图形 (12)

指定 (4)

样式化 (4)

坐标 (4)

区域 (10)

应用 (3)

属性和关系 (5)

巧妙范例 (1)

参见

相关指南

历史

文本

CMS

APA

BibTeX

BibLaTeX