Wolfram 语言与系统参考资料中心

Mod

Mod[m,n]

用来给出 m 除以 n 得到的余数.

Mod[m,n,d]

使用一个偏移量 d.

范例

打开所有单元关闭所有单元

基本范例 (4)

计算 5 模 3：

Wolfram Language code: Mod[5, 3]

5 除以 3 的余数，从 1 开始：

Wolfram Language code: Mod[5, 3, 1]

图示固定模的序列：

Wolfram Language code: DiscretePlot[Mod[n, 8], {n, 50}]

图示模变化时的序列：

Wolfram Language code: DiscretePlot[Mod[100, m], {m, 50}]

范围 (13)

数值运算 (6)

对整数进行计算：

Wolfram Language code: Mod[17, 5]

设置偏移量，进行计算：

Wolfram Language code: Mod[17, 5, 1]

Mod 适用于整数：

Wolfram Language code: Mod[17, 5]

有理数：

Wolfram Language code: Mod[5 / 2, 2]

实数：

Wolfram Language code: Mod[Sqrt[28], 3]

复数：

Wolfram Language code: Mod[5 + 3I, 2]

精确数：

Wolfram Language code: Mod[Pi, 2]

非精确数：

Wolfram Language code: Mod[3.14, 2.]

用大整数进行计算：

Wolfram Language code: Mod[10 ^ 10000, 10007]

Mod 作用于列表的各项：

Wolfram Language code: Mod[{1, 2, 3, 4, 5}, 3]

TraditionalForm 格式：

Wolfram Language code: Mod[a, n]//TraditionalForm

符号运算 (7)

求解模方程：

Wolfram Language code: Reduce[Mod[2x + 1, 5] == Mod[x, 7] && 0 < x < 50, x]

在求和时使用 Mod：

Wolfram Language code: Sum[Mod[n ^ 2, 2], n]

积：

Wolfram Language code: Product[Sin[(1/1 + Mod[i ^ 2, 3])], i]

化简表达式：

Wolfram Language code: FullSimplify[Mod[a, -b] + Mod[-a, b] == 0]

识别 Mod 序列：

Wolfram Language code: FindSequenceFunction[{1, 2, 3, 4, 0, 1, 2, 3, 4, 0}, n]

递归方程：

Wolfram Language code: DifferenceRootReduce[Mod[k, 3], k]

DirichletTransform：

Wolfram Language code: DirichletTransform[Mod[n, 2], n, s]

母函数：

Wolfram Language code: GeneratingFunction[Mod[n, 4], n, x]

Wolfram Language code: ExponentialGeneratingFunction[Mod[n, 4], n, x]//FullSimplify

应用 (19)

基本应用 (3)

Mod 的前 20 个值：

Wolfram Language code:

Grid[{Prepend[Range[20], "n"], Prepend[Table[CarmichaelLambda[n], {n, 20}], "TraditionalFormλ(n)"]}, Background -> {None, {LightYellow, White}}, Dividers -> Lighter[Gray, .5], Spacings -> {Automatic, .8}]

绘制序列，模数不变：

Wolfram Language code: DiscretePlot[Mod[n, 8], {n, 50}]

改变模数，绘制序列：

Wolfram Language code: DiscretePlot[Mod[100, m], {m, 50}]

Mod[n,8] 的母函数：

Wolfram Language code: ModGF[z_] = GeneratingFunction[Mod[n, 8], n, z]

Wolfram Language code:

GraphicsRow[{Plot[ModGF[x], {x, 0, 1}], ContourPlot[Re[ModGF[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

指数生成函数：

Wolfram Language code: ModEGF[z_] = ExponentialGeneratingFunction[Mod[n, 8], n, z];

Wolfram Language code:

GraphicsRow[{Plot[ModEGF[x], {x, 0, 16}], ContourPlot[Re[ModEGF[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

Dirichlet 级数：

Wolfram Language code: ModL[s_] = Sum[Mod[n, 8] / n ^ s, {n, 1, Infinity}]

Wolfram Language code: GraphicsRow[{Plot[ModL[x], {x, 0, 16}], ContourPlot[Re[ModL[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

数字标识符 (1)

给出 International Standard Book Number (ISBN)，查看是否有效：

Wolfram Language code: ISBNs = {"0394380495", "1092312213", "0821801236", "9781944183"};

如果，则为有效的 ISBN，其中每个是 ISBN 的第位数：

Wolfram Language code:

ValidISBNQ[str_] := Module[
	{l}, l = ToExpression[StringPartition[str, 1]];
	If[Mod[Sum[l[[i]]i, {i, 10}], 11] == 0, True, False]
	];

查看是否每个 ISBN 都是有效的：

Wolfram Language code: ValidISBNQ /@ ISBNs

加密 (2)

构建 RSA 类的加密方案. 从模数开始：

Wolfram Language code:

{p, q} = Prime[RandomInteger[{10 ^ 4, 10 ^ 5}, {2}]];
n = p q

求模 n 乘法群的通用指数：

Wolfram Language code: λ = CarmichaelLambda[n]

私钥：

Wolfram Language code: d = NestWhile[#1 + 1& , Round[n / 3], GCD[λ, #1] =!= 1&]

公钥：

Wolfram Language code: e = ModularInverse[d, λ]

加密一条消息：

Wolfram Language code: PowerMod[ToCharacterCode["RSA in Mathematica"], e, n]

解密：

Wolfram Language code: FromCharacterCode[PowerMod[%, d, n]]

用 Mod 创建凯撒密码，通过对字母表进行移位来加密消息：

Wolfram Language code:

EncryptCaesar[msg_, key_] := Module[
	{encr, decr, x, n, nums, res}, 
	encr = Transpose[{Alphabet[], Range[0, 25]}] /. {x_String, n_Integer} -> (x -> n);
	decr = Reverse[encr, 2];
	nums = StringPartition[ToLowerCase[msg], 1] /. encr;
	res = (Mod[nums + key, 26]) /. decr//StringJoin
	];
DecryptCaesar[msg_, key_] := EncryptCaesar[msg, -key];

用密钥加密一条消息：

Wolfram Language code:

key = 315;
msg = "bewaretheidesofmarch";
EncryptCaesar[msg, key]

对消息进行解密：

Wolfram Language code: DecryptCaesar[%, key]

数论 (6)

检测形为的数字为素数还是合成数：

Wolfram Language code: MersennePrimeQ[n_] := TrueQ[Last[NestList[Mod[# ^ 2 - 2, 2 ^ n - 1]&, 4, n - 2]] == 0];

Wolfram Language code: Select[Range[3, 100], MersennePrimeQ]

选择 100 以下、形为的素数：

Wolfram Language code: Select[Array[Prime, PrimePi[100]], Mod[#, 6] == 1&]

费马小定理：

Wolfram Language code: GCD[7, 11]

Wolfram Language code: Mod[7 ^ (11 - 1), 11]

欧拉定理：

Wolfram Language code: GCD[7, 12]

Wolfram Language code: Mod[7 ^ EulerPhi[12], 12]

Wilson 定理：

Wolfram Language code: FunctionExpand[Mod[(p - 1)!, p], p∈Primes]

定义加法模 2 的记号：

Wolfram Language code: x_⊕y_ := Mod[x + y, 2]

Wolfram Language code: (1⊕0)⊕1

用 Mod 求解线性同余方程组：

Wolfram Language code:

r = {3, 5, 7};
m = {2, 3, 5};
M = (Times@@m/m);
Mod[Dot[r, #^EulerPhi[#]& /@ M], Times@@m]

Wolfram Language code: ChineseRemainder[r, m]

计算机科学 (3)

创建一个使用当前时间作为种子的随机数生成器：

Wolfram Language code:

x[0] = UnixTime[]
x[k_] := Mod[a^kx[0], m];

选择模数和基数：

Wolfram Language code:

m = 2147483647;
a = 16807;

生成 1000 个 0 和 1 之间的随机数：

Wolfram Language code: Histogram[Table[x[i] / m, {i, 0, 1000}], 10]

循环提取列表的一部分：

Wolfram Language code: {a, b, c}[[Mod[Range[10], 3, 1]]]

矩阵的逆的模运算：

Wolfram Language code: A = {{3, 4}, {2, 5}};

先计算伴随矩阵：

Wolfram Language code:

MinorMatrix[Mat_List ? MatrixQ] := Map[Reverse, Minors[Mat], {0, 1}]
CofactorMatrix[Mat_List ? MatrixQ] := MapIndexed[#1 (-1) ^ (Plus@@#2)&, MinorMatrix[Mat], {2}]
MatrixAdjoint[Mat_] := Transpose[CofactorMatrix[Mat]];

然后计算矩阵的模逆：

Wolfram Language code:

ModularInverseMatrix[Mat_, m_] := Mod[ModularInverse[Det[Mat], m]MatrixAdjoint[Mat], m];
ModularInverseMatrix[A, 13]

查看逆是否给出正确的结果：

Wolfram Language code: Mod[A.%, 13]

政治、经济和社会科学 (2)

根据哈希算法将内存地址分配给社会安全号：

Wolfram Language code:

socials = {344401659, 325510778, 212228844, 329938157, 047900151, 372500191, 034367980, 546332190, 509496993, 132489973};

为每个社安号码分配一个位置，确保没有冲突：

Wolfram Language code:

AssignSingle[social_, locations_] := Module[
	{i = 0}, 
	While[MemberQ[locations[[ ;; , 2]], h[i, social]], i++];
	Append[locations, {social, h[i, social]}]
	];
AssignAll[socials_] := Module[
	{l = Length[socials], locations = {}}, 
	For[i = 1, i ≤ l, i++, locations = AssignSingle[socials[[i]], locations]];
	locations
	];

计算结果：

Wolfram Language code: AssignAll[socials]

计算单个社安号的哈希：

Wolfram Language code:

m = 4969;
num = 10 ^ 3 + 1;
g[k_] := Mod[k + 1, m - 2];
hash[k_] := Mod[k + num g[k], m];
social = 344401659;

Wolfram Language code: hash[social]

其他应用 (2)

模拟在 noncommensurate 盒中弹跳的粒子：

Wolfram Language code: Graphics[Line[Table[Mod[t, {Sqrt[2], 1}], {t, 0, 15, .001}]]]

十二平均律系统：

Wolfram Language code: Needs["Music`"]

Wolfram Language code: Sound[SoundNote[{"CSharp", "DFlat"}, 1, "Piano"]]

相差 1200 cents 的音符被视为来自同样的同余类：

Wolfram Language code: Mod[HertzToCents[{Csharp1, Csharp2}], 1200]

属性和关系 (7)

Mod 是周期函数：

Wolfram Language code: FunctionPeriod[Mod[n, 3], n]

Mod 对所有复数有定义：

Wolfram Language code: FunctionDomain[Mod[n, 3], n]

值域：

Wolfram Language code: FunctionRange[Mod[n, 3], n, m]

Mod 具有传递性. 如果和，则：

Wolfram Language code: Mod[5, 3] == Mod[2, 3]

Wolfram Language code: Mod[2, 3] == Mod[8, 3]

Wolfram Language code: Mod[8, 3] == Mod[5, 3]

如果整除，则：

Wolfram Language code: Divisible[8, 2]

Wolfram Language code: Mod[8, 2]

QuotientRemainder[a,n] 与 Mod[a,n] 相同：

Wolfram Language code: QuotientRemainder[17, 6]//Last

Wolfram Language code: Mod[17, 6]

用 PowerMod 计算模逆：

Wolfram Language code: PowerMod[3, -1, 7]

检查结果：

Wolfram Language code: Mod[3 5, 7]

结果与模数的符号相同：

Wolfram Language code: Mod[{5, -5}, 3]

Wolfram Language code: Mod[{5, -5}, -3]

对于正实数 x，Mod[x,1] 给出 x 的小数部分：

Wolfram Language code: Mod[3.14, 1]

Wolfram Language code: FractionalPart[3.14]

可能存在的问题 (1)

某些计算可能需要比默认值更高的内部精度：

Wolfram Language code: Mod[GoldenRatio ^ 1000, 1]

重置 $MaxExtraPrecision 的值：

Wolfram Language code: Block[{$MaxExtraPrecision = Infinity}, Mod[GoldenRatio ^ 1000, 1]]

巧妙范例 (4)

模 2 二项式系数：

Wolfram Language code: ArrayPlot[Table[Mod[Binomial[i, j], 2], {i, 0, 63}, {j, 0, 63}]]

加性元胞自动机：

Wolfram Language code: ArrayPlot[CellularAutomaton[{Mod[Total[#], 4]&, {}, 1}, {{1}, 0}, 50]]

绘制 Ulam 螺旋，其中根据它们的同余模 49 对数字着色：

Wolfram Language code:

ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table
	[(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n]

Wolfram Language code: ArrayPlot[Mod[ulam[109], 109], ColorFunction -> "TemperatureMap"]

模加法表：

Wolfram Language code: ArrayPlot[Table[Mod[a + b, 4], {a, 0, 8}, {b, 0, 8}], ColorFunction -> "Rainbow"]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

Mod

更多信息

范例

基本范例 (4)

范围 (13)

数值运算 (6)

符号运算 (7)

应用 (19)

基本应用 (3)

数字标识符 (1)

加密 (2)

数论 (6)

计算机科学 (3)

政治、经济和社会科学 (2)

其他应用 (2)

属性和关系 (7)

可能存在的问题 (1)

巧妙范例 (4)

文本

CMS

APA

BibTeX

BibLaTeX

Mod

更多信息

范例

基本范例 (4)

范围 (13)

数值运算 (6)

符号运算 (7)

应用 (19)

基本应用 (3)

数字标识符 (1)

加密 (2)

数论 (6)

计算机科学 (3)

政治、经济和社会科学 (2)

其他应用 (2)

属性和关系 (7)

可能存在的问题 (1)

巧妙范例 (4)

参见

技术笔记

相关指南

相关链接

历史

文本

CMS

APA

BibTeX

BibLaTeX