WOLFRAM

Wolfram 语言与系统参考资料中心

SASTriangle[a,γ,b]

返回一个实心三角形，其中边长分别为 a 和 b，它们之间的角为 γ.

更多信息和选项
Details and Options Details and Options
背景
范例  
基本范例  
范围  
图形  
规范  
样式  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

SASTriangle

SASTriangle[a,γ,b]

返回一个实心三角形，其中边长分别为 a 和 b，它们之间的角为 γ.

更多信息和选项

  • SASTriangle 也称为边角边三角形.
  • SASTriangle 可以作为二维图形中的基元，和二维空间中的几何区域.
  • SASTriangle 的给定（蓝色）和计算所得（红色）参数：
  • SASTriangle 返回 Triangle，其中 A 位于原点，B 位于正 轴，而 C 位于半平面 .
  • SASTriangle 中长度 a 和 b 是任意正数，角度 γ 严格位于 0 和 之间.

背景

  • SASTriangle 构建了一个边-角-边三角形. 具体来讲，SASTriangle[a,γ,b] 表示 TemplateBox[{}, Reals]^2 中的一个 Triangle，顶点 、 和 分别位于原点、正 轴和上半平面，a 和 b 为顶点 和 所对边的边长，γ∠ACB. 根据 SAS 定理，这样指定的三角形是唯一的（符合几何全等性）. SASTriangle 允许边长 a 和 b 为任意正数，角 γ 为满足 的正值. SASTriangle 的参数可以为精确表达式或近似数字表达式.
  • 可将由 SASTriangle 返回的 Triangle 对象用作二维图形基元或几何区域.
  • SASTriangle 与几个其他符号相关. AASTriangle、ASATriangle 和 SSSTriangle 返回用不同的角和/或边指定构建的二维三角形. SASTriangle 是 Triangle 的特例，因为对于 xSqrt[a^2+b^2-2 a b Cos[γ]]，y(b^2-a bCos[γ])/Sqrt[a^2+b^2-2 a b Cos[γ]] 和 z(a b Sin[γ])/Sqrt[a^2+b^2-2 a b Cos[γ]]，SASTriangle[a,γ,b] 等价于 Triangle[{{0,0},{x,0},{y,z}}].

范例

打开所有单元 关闭所有单元

基本范例  (4)

三角形，其中 ， 和 ：

Wolfram Language code: SASTriangle[1, Pi / 2, 2]

SASTriangle：

Wolfram Language code: Graphics[SASTriangle[1, Pi / 2, 2]]

应用于 SASTriangle 的不同样式：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2]; {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

面积和中心：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: Area[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

范围  (14)

图形  (4)

规范  (2)

SASTriangle 计算得到 Triangle，其中一个点位于原地，一条边位于 轴：

Wolfram Language code: t = SASTriangle[1, Pi / 4, 2]
Wolfram Language code: Graphics[{Pink, t}, Frame -> True]

具有符号式边长的三角形：

Wolfram Language code: SASTriangle[1, Pi / 2, b]

绘制图形：

Wolfram Language code: Table[Graphics[%, ImageSize -> Tiny, PlotLabel -> b], {b, 0.5, 3.5}]

样式  (2)

颜色指令指定了面的颜色：

Wolfram Language code: Table[Graphics[{c, SASTriangle[1, Pi / 2, 2]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定内部和边界的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Thick, Dashed, Blue]], SASTriangle[1, Pi / 2, 2]}]

区域  (10)

嵌入维度是三角形空间的维度：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

几何维度是形状维度本身：

Wolfram Language code: RegionDimension[ℛ]

隶属检测：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: {RegionMember[ℛ, {1, 1 / 2}], RegionMember[ℛ, {2, 1}]}

隶属条件：

Wolfram Language code: RegionMember[ℛ, {x, y}]

面积：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: {Area[ℛ], RegionMeasure[ℛ]}

质心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics[{{Pink, ℛ}, {Black, Point[c]}}]

从点到 SASTriangle 的距离：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: RegionDistance[ℛ, {2, 1}]//Simplify

可视化：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> 5], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 4}, {y, -2, 3}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

从一个点的有符号的距离：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: SignedRegionDistance[ℛ, {1, 1 / 3}]

现在绘制图线：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 3}, {y, -1, 2}, MeshFunctions -> {#3&}, Mesh -> {{0}}, MeshShading -> {Red, Green}]

最近点：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: RegionNearest[ℛ, {2, 1}]

可视化：

Wolfram Language code: pts = Table[RegionCentroid[ℛ] + 2{Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

三角形是有界的：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: BoundedRegionQ[ℛ]

求范围：

Wolfram Language code: rr = RegionBounds[ℛ]
Wolfram Language code: Graphics[{ℛ, {EdgeForm[{Dashed, Red}], Opacity[0.1, Yellow], Cuboid@@Transpose[rr]}}]

在 SASTriangle 上求 Integrate：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: Integrate[1, {x, y}∈ℛ]
Wolfram Language code: Integrate[x y, {x, y}∈ℛ]

在它上面求优化：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: Minimize[{(x - 1)^2(3y - 1)^2 + 1, {x, y}∈ℛ}, {x, y}]

在 SASTriangle 上求解方程：

Wolfram Language code: ℛ = SASTriangle[1, Pi / 2, 2];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

应用  (2)

一个有两边相等的三角形是一个等腰三角形：

Wolfram Language code: IsoscelesTriangle[s_, α_] := SASTriangle[s, α, s]
Wolfram Language code: t = IsoscelesTriangle[1, π / 2]

可视化：

Wolfram Language code: Region[t]

求它的面积：

Wolfram Language code: Area@IsoscelesTriangle[s, α]

一个 SASTriangle 的外接圆可以用 Circumsphere 找到：

Wolfram Language code: tri = SASTriangle[2, Pi / 3, 3.]

外接圆经过三个顶点：

Wolfram Language code: circ = Circumsphere[First@tri];
Wolfram Language code: Graphics[{{LightGray, circ}, {LightBlue, tri}, {Black, Point[First@tri]}}]

找到三角形每条边的中点：

Wolfram Language code: midpts = RegionCentroid[Line[#]]& /@ Subsets[First@tri, {2}]
Wolfram Language code: Graphics[{{LightBlue, tri}, Point[midpts]}]

垂直平分线是从外心到中点的线：

Wolfram Language code: center = First[circ]; bisectors = Line[{center, #}]& /@ midpts;
Wolfram Language code: Graphics[{{LightBlue, tri}, {Point[center], Point[midpts]}, {Red, Dashed, bisectors}}]

属性和关系  (2)

SASTriangle 是 Triangle 的一个特例：

Wolfram Language code: SASTriangle[a, γ, b]

任意 SASTriangle 可以使用 Polygon 表示：

Wolfram Language code: Subscript[ℛ, 1] = SASTriangle[3, Pi / 2, 4]; Subscript[ℛ, 2] = Polygon[{{0, 0}, {5, 0}, {(16/5), (12/5)}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (1)

改变一个角：

Wolfram Language code: Graphics[{Opacity[0.15], Table[{ColorData["Rainbow"][Rescale[α, {5π / 10, 9π / 10}]], SASTriangle[1, α, 1]}, {α, 5π / 10, 9π / 10, π / 30}]}]
Wolfram Research (2014)，SASTriangle，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SASTriangle.html.

文本

Wolfram Research (2014)，SASTriangle，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SASTriangle.html.

CMS

Wolfram 语言. 2014. "SASTriangle." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SASTriangle.html.

APA

Wolfram 语言. (2014). SASTriangle. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SASTriangle.html 年

BibTeX

@misc{reference.wolfram_2026_sastriangle, author="Wolfram Research", title="{SASTriangle}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/SASTriangle.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_sastriangle, organization={Wolfram Research}, title={SASTriangle}, year={2014}, url={https://reference.wolfram.com/language/ref/SASTriangle.html}, note=[Accessed: 12-September-2026]}