WOLFRAM

Wolfram 语言与系统参考资料中心

SignTest[data]

检验 data 的中位数是否为0.

SignTest[{data1,data2}]

检验 data1– data2 的中位数是否为0.

SignTest[dspec,μ0]

对 μ0 检验一个位置量数.

SignTest[dspec,μ0,"property"]

返回 "property" 的值.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
检验  
报告  
选项  
AlternativeHypothesis  
MaxIterations  
Method  
SignificanceLevel  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

SignTest

SignTest[data]

检验 data 的中位数是否为0.

SignTest[{data1,data2}]

检验 data1– data2 的中位数是否为0.

SignTest[dspec,μ0]

对 μ0 检验一个位置量数.

SignTest[dspec,μ0,"property"]

返回 "property" 的值.

更多信息和选项

  • SignTest 检验零假设 与替代假设 ：
  • data
    {data1,data2}
  • 其中 μ 是 data 的总体中位数，μ12是两个数据集 的配对差中位数.
  • 默认情况下，返回一个概率值或者 值.
  • 一个小的 值表明 不可能为真.
  • dspec 中的数据可以是单变量 {x1,x2,…} 或者多变量 {{x1,y1,…},{x2,y2,…},…}.
  • 如果给定两个样本，则它们必须具有相同的长度.
  • 变量 μ0 可以是一个实数，或者长度等于数据维度的一个实向量.
  • SignTest[dspec,μ0,"HypothesisTestData"] 返回一个 HypothesisTestData 对象 htd，可以使用 htd["property"] 的形式来提取额外检验结果和属性.
  • SignTest[dspec,μ0,"property"] 可以用于直接给出 "property" 值.
  • 与检验结果的报告相关的属性包括：
  • "DegreesOfFreedom"检验中所用的自由度
    "PValue" 值列表
    "PValueTable" 值组成的格式化表格
    "ShortTestConclusion"检验结论的简短描述
    "TestConclusion"检验结论的描述
    "TestData"检验统计量和 值对的列表
    "TestDataTable" 值和检验统计量组成的格式化表格
    "TestStatistic"检验统计量组成的列表
    "TestStatisticTable"检验统计量组成的格式化表格
  • 对于单变量样本，SignTest 执行对成对样本的中位数的符号检验. 假设检验统计量服从BinomialDistribution[n,1/2]，其中 n 是 dspec 中不等于 μ0 的元素数目.
  • 对于多变量样本，SignTest 使用空间符号对成对样本执行一个仿射不变检验. 假设检验统计量服从一个 ChiSquareDistribution[dim]，其中 dim 是 dspec 的维度.
  • 可以使用以下选项：
  • AlternativeHypothesis "Unequal"备择假设的不等性
    MaxIterations Automatic多变量中位数检验的最大迭代
    Method Automatic用于 -值的方法
    SignificanceLevel 0.05用于诊断和报告的分界点
  • 对于 SignTest，选择一个临界值 ，使得当且仅当 时，否定 . 用于 "TestConclusion" 和 "ShortTestConclusion" 属性的 值由 SignificanceLevel 选项控制. 默认情况下， 设为 0.05.

范例

打开所有单元 关闭所有单元

基本范例  (4)

检验一个总体的中位数是否为零：

Wolfram Language code: data = RandomVariate[NormalDistribution[], 100];
Wolfram Language code: SignTest[data]

检验多变量总体的空间中位数是否是某个固定的值：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{0, 0, 0}, IdentityMatrix[3]], 10^3];
Wolfram Language code: SignTest[data, {.5, .5, .5}]

计算检验统计量：

Wolfram Language code: SignTest[data, {.5, .5, .5}, "TestStatistic"]

将成对数据的中位数差值与某个特定值比较：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{2, 0}, {{1, .75}, {.75, 1}}], 1000];
Wolfram Language code: SignTest[Transpose@data, 2]

在一个表格中报告检验结果：

Wolfram Language code: SignTest[Transpose@data, 2, "TestDataTable"]

创建一个 HypothesisTestData 对象，用以进行重复属性提取：

Wolfram Language code: data = RandomVariate[StudentTDistribution[4], 100];
Wolfram Language code: ℋ = SignTest[data, Automatic, "HypothesisTestData"]

可用属性列表：

Wolfram Language code: ℋ["Properties"]

提取单个属性或者属性列表：

Wolfram Language code: ℋ["TestData"]
Wolfram Language code: ℋ["TestDataTable", "PValue", "TestStatistic"]

范围  (13)

检验  (10)

检验 与 ：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 1], 500]; data2 = RandomVariate[NormalDistribution[3, 1], 500];

当中位数接近 μ0 时， 值通常较大：

Wolfram Language code: SignTest[data1]

当位置（location）远离 μ0 时， 值通常较小：

Wolfram Language code: SignTest[data2]

使用 Automatic 等价于检验中位数是否为0：

Wolfram Language code: data = RandomVariate[NormalDistribution[0, 1], 500];
Wolfram Language code: SignTest[data, 0]
Wolfram Language code: SignTest[data, Automatic]

检验 与 ：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[3, 1], 500]; data2 = RandomVariate[NormalDistribution[0, 1], 500];

当中位数接近 μ0 时， 值通常较大：

Wolfram Language code: SignTest[data1, 3]

当位置远离 μ0 时， 值通常较小：

Wolfram Language code: SignTest[data2, 3]

检验多变量总体的中位数向量是否为零向量：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{.1, 0, -.05, 0}, IdentityMatrix[4]], 10^3];
Wolfram Language code: SignTest[data]

也可以对 {0.1,0,-0.05,0} 进行检验：

Wolfram Language code: SignTest[data, {0.1, 0, -.05, 0}]

检验 与 ：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[0, 1], 100]; data2 = RandomVariate[NormalDistribution[1, 1], 100]; data3 = RandomVariate[NormalDistribution[0, 2], 100];

当位置不相等时， 值通常较小：

Wolfram Language code: SignTest[{data1, data2}, 0]

当位置相等时， 值通常较大：

Wolfram Language code: SignTest[{data1, data3}, 0]

检验 与 ：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[3, 1], 100]; data2 = RandomVariate[NormalDistribution[0, 1], 100];

数据集的顺序影响检验结果：

Wolfram Language code: SignTest[{data1, data2}, 3]
Wolfram Language code: SignTest[{data2, data1}, 3]

检验两个多变量总体的中位数差异向量是否为零向量：

Wolfram Language code: data1 = RandomVariate[MultinormalDistribution[{.5, 0, -.5, 0}, IdentityMatrix[4]], 10^2];
Wolfram Language code: data2 = RandomVariate[MultinormalDistribution[{-.5, 0, .5, 0}, IdentityMatrix[4]], 10^2];
Wolfram Language code: SignTest[{data1, data2}]

或者，对 {1,0,-1,0} 进行检验：

Wolfram Language code: SignTest[{data1, data2}, {1, 0, -1, 0}]

创建一个 HypothesisTestData 对象，用以进行重复属性提取：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = SignTest[data, 0, "HypothesisTestData"];

可用于提取的属性：

Wolfram Language code: ℋ["Properties"]

从 HypothesisTestData 对象中提取某些属性：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = SignTest[data, 0, "HypothesisTestData"];

值和检验统计量：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatistic"]

同时提取任意数目的属性：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^4}];
Wolfram Language code: ℋ = SignTest[data, 0, "HypothesisTestData"];

值和检验统计量：

Wolfram Language code: ℋ["PValue", "TestStatistic"]

报告  (3)

将检验结果制作成表格：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 20}];
Wolfram Language code: ℋ = SignTest[data, 0, "HypothesisTestData"];
Wolfram Language code: ℋ["TestDataTable"]

将检验表格提取项目，制作成定制的报告：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {1000, 25}];
Wolfram Language code: res = Table[SignTest[v, 0, "TestData"], {v, data}];
Wolfram Language code: ListPlot[res, Filling -> Axis]

将 值或者检验统计量制作成表格：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 10^2}];
Wolfram Language code: ℋ = SignTest[data, 0, "HypothesisTestData"];
Wolfram Language code: ℋ["PValueTable"]

来自表格的 值：

Wolfram Language code: ℋ["PValue"]
Wolfram Language code: ℋ["TestStatisticTable"]

来自表格的检验统计量：

Wolfram Language code: ℋ["TestStatistic"]

选项  (9)

AlternativeHypothesis  (3)

默认情况下，执行双侧检验：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];

检验 与 ：

Wolfram Language code: SignTest[data, 0, AlternativeHypothesis -> "Unequal"]
Wolfram Language code: SignTest[data, 0, AlternativeHypothesis -> Automatic]

执行双侧检验或者一个单侧检验：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];

检验 与 ：

Wolfram Language code: SignTest[data, 0, AlternativeHypothesis -> "Unequal"]

检验 与 ：

Wolfram Language code: SignTest[data, 0, AlternativeHypothesis -> "Less"]

检验 与 ：

Wolfram Language code: SignTest[data, 0, AlternativeHypothesis -> "Greater"]

当给定 μ0 时，执行具有单侧备择假设的检验：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[2.9, 1], 1000]; data2 = RandomVariate[NormalDistribution[0, 1], 1000];
Wolfram Language code: Mean[data1 - data2]

检验 与 ：

Wolfram Language code: SignTest[{data1, data2}, 3, AlternativeHypothesis -> "Less"]

检验 与 ：

Wolfram Language code: SignTest[{data1, data2}, 2.9, AlternativeHypothesis -> "Less"]

MaxIterations  (2)

设置最大迭代次数用于多变量检验：

Wolfram Language code: data1 = RandomVariate[BinormalDistribution[.5], 25]; data2 = RandomVariate[BinormalDistribution[.5], 25];

默认情况下，允许500次迭代：

Wolfram Language code: SignTest[{data1, data2}, Automatic, MaxIterations -> 500]
Wolfram Language code: SignTest[{data1, data2}, Automatic, MaxIterations -> Automatic]

设置最大迭代次数可能会导致收敛性的缺乏：

Wolfram Language code: BlockRandom[SeedRandom[2]; data1 = RandomVariate[BinormalDistribution[.5], 25]; data2 = RandomVariate[BinormalDistribution[.5], 25];]

值不是相等的：

Wolfram Language code: SignTest[{data1, data2}, Automatic, MaxIterations -> 1]
Wolfram Language code: SignTest[{data1, data2}, Automatic, MaxIterations -> Automatic]

Method  (3)

默认情况下，使用单变量数据的 BinomialDistribution 计算 值：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 100}];
Wolfram Language code: SignTest[data, 0, Method -> Automatic]
Wolfram Language code: SignTest[data, 0, Method -> "Permutation"]

对于单变量数据使用渐近方法：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {2, 500}];
Wolfram Language code: SignTest[data, 0, Method -> "Asymptotic"]
Wolfram Language code: SignTest[data, 0, Method -> "Permutation"]

对于对变量数据，只有渐近的结果：

Wolfram Language code: data = RandomVariate[NormalDistribution[], {35, 2}];
Wolfram Language code: SignTest[data, 0, Method -> "Asymptotic"]
Wolfram Language code: SignTest[data, 0, Method -> "Permutation"]

SignificanceLevel  (1)

对于 "TestConclusion" 和 "ShortTestConclusion" 也可使用显著性水平：

Wolfram Language code: BlockRandom[SeedRandom[1];data = RandomVariate[NormalDistribution[0, 1], {2, 100}]];
Wolfram Language code: ℋ1 = SignTest[data, .2, "HypothesisTestData", SignificanceLevel -> .05];
Wolfram Language code: ℋ2 = SignTest[data, .2, "HypothesisTestData", SignificanceLevel -> .001];
Wolfram Language code: ℋ1["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ2["TestConclusion"]//TraditionalForm
Wolfram Language code: ℋ1["ShortTestConclusion"]
Wolfram Language code: ℋ2["ShortTestConclusion"]

应用  (2)

对 8 个病人进行新的睡眠辅助方法检验. 对某个晚上，分别记录每个病人服用药物和服用安慰剂入睡所花的分钟数：

Wolfram Language code: sleepAid = {12, 9, 11, 21, 17, 22, 18, 11}; placebo = {21, 16, 8, 36, 28, 20, 29, 22};
Wolfram Language code: SmoothHistogram[{sleepAid, placebo}]

SignTest 没有检测到睡眠辅助药物和安慰剂的不同：

Wolfram Language code: SignTest[{sleepAid, placebo}, 0, "TestDataTable"]

虽然数据集很小，但也通过了正态性检验：

Wolfram Language code: DistributionFitTest /@ {sleepAid, placebo}

一个效能更好的 PairedTTest 显示服用睡眠辅助药物，入睡所花时间更短：

Wolfram Language code: PairedTTest[{sleepAid, placebo}, 0, "TestDataTable"]

10 个数学和科学成绩很低的学生被要求参加为期两个星期的强化数学和科学集训项目. 在项目后，举行一个测验，该测验与原考试类似. 这些学生在两次考试的数学和科学部分的得分如下：

Wolfram Language code: preMath = {64, 51, 45, 37, 60, 67, 51, 59, 65, 53}; preSci = {58, 46, 62, 40, 58, 34, 69, 31, 26, 58}; postMath = {84, 68, 73, 72, 78, 72, 70, 65, 81, 78}; postSci = {66, 69, 64, 70, 60, 57, 59, 68, 59, 56};
Wolfram Language code: pre = Transpose[{preMath, preSci}]; post = Transpose[{postMath, postSci}];
Wolfram Language code: ContourPlot[Evaluate@PDF[SmoothKernelDistribution[N[post - pre]], {m, s}], {m, -8, 50}, {s, -25, 50}, PlotRange -> All]

整体上看，成绩有显著的提高：

Wolfram Language code: SignTest[{Transpose[{preMath, preSci}], Transpose[{postMath, postSci}]}, 0, "TestDataTable"]

对每个分量的 Bonferroni-corrected 检验，表明数学成绩本身对所检测到的进步起作用：

Wolfram Language code: α = .05;
Wolfram Language code: SignTest[{preSci, postSci}, 0, "ShortTestConclusion", SignificanceLevel -> α / 2]
Wolfram Language code: SignTest[{preMath, postMath}, 0, "ShortTestConclusion", SignificanceLevel -> α / 2]

属性和关系  (6)

从概念上讲，SignTest 计算一个数据集中正号的数目：

Wolfram Language code: data = RandomVariate[BinomialDistribution[10, .5], 100];
Wolfram Language code: μ = 10 * .5;
Wolfram Language code: sgn = Sign[data - μ];
Wolfram Language code: T = Count[sgn, 1]

对于单变量数据，忽略零，检验统计量服从 BinomialDistribution：

Wolfram Language code: n = Count[sgn, Except[0]];
Wolfram Language code: Probability[x <= T, xBinomialDistribution[n, .5]]
Wolfram Language code: SignTest[data, μ, "TestDataTable", AlternativeHypothesis -> "Less"]

对于定位而言，SignTest 通常没有其它假设检验强大：

Wolfram Language code: data = RandomVariate[NormalDistribution[.5, 1], {1000, 25}];
Wolfram Language code: Subscript[p, sign] = Table[SignTest[i], {i, data}]; Subscript[p, sr] = Table[SignedRankTest[i, VerifyTestAssumptions -> None], {i, data}]; Subscript[p, T] = Table[TTest[i, VerifyTestAssumptions -> None], {i, data}];
Wolfram Language code: Probability[x < .05, xSubscript[p, sign]]//N
Wolfram Language code: Probability[x < .05, xSubscript[p, sr]]//N
Wolfram Language code: Probability[x < .05, xSubscript[p, T]]//N

对于多变量数据，当计算检验统计量时，使用空间符号：

Wolfram Language code: SpatialSign[d_] := With[{norm = Norm[d]}, If[norm == 0, ConstantArray[0, Length[d]], d / norm]]
Wolfram Language code: data1 = RandomVariate[MultinormalDistribution[{0, 0}, IdentityMatrix[2]], 100]; data2 = RandomVariate[MultinormalDistribution[{2, 1}, IdentityMatrix[2]], 100];

当空间中位数非零时，空间符号倾向于形成聚类：

Wolfram Language code: {ListPlot[SpatialSign /@ data1, AspectRatio -> 1, PlotRange -> {{-1, 1}, {-1, 1}}], ListPlot[SpatialSign /@ data2, AspectRatio -> 1, PlotRange -> {{-1, 1}, {-1, 1}}]}

聚类的数目由检验统计量计算：

Wolfram Language code: t1 = SignTest[data1, {0, 0}, "TestStatistic"]
Wolfram Language code: t2 = SignTest[data2, {0, 0}, "TestStatistic"]

检验统计量服从 ChiSquareDistribution：

Wolfram Language code: p = Dimensions[data1][[2]]
Wolfram Language code: Probability[x > t1, xChiSquareDistribution[p]]
Wolfram Language code: SignTest[data1]

对于多变量数据，检验统计量是仿射不变的：

Wolfram Language code: data = RandomVariate[MultinormalDistribution[{0, 0}, IdentityMatrix[2]], 100];
Wolfram Language code: 𝒯 = AffineTransform[{{{1, 2}, {3, 4}}, {1, 2}}];
Wolfram Language code: SignTest[data, {0, 0}, "TestDataTable"]
Wolfram Language code: SignTest[𝒯[data], 𝒯[{0, 0}], "TestDataTable"]

只有当输入是一个 TimeSeries 时，符号检测才会作用于值（values）：

Wolfram Language code: ts = TemporalData[TimeSeries, {{{1.224578634529677, 0.47929635789978015, 0.6572781300178168, 0.21496048742669355, 0.7299608014554928, -0.2495111111278263, -1.3286551762002712, 0.552725018274874, 0.19272112205837066, 1.1809144012420882, -1.1671 ... 40938613662046, 1.052394590214582, 0.9345044123980388, 0.38537803109557855, -0.48660931166089394, -0.71203560340161}}, {{0, 100, 1}}, 1, {"Continuous", 1}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: SignTest[ts]
Wolfram Language code: SignTest[ts["Values"]]

当输入是一个 TemporalData 时，符号检测一起作用于所有值：

Wolfram Language code: td = TemporalData[Automatic, {{{-0.25275046867718637, -0.7175779198306353, -1.9370139837317764, 0.006665621735740701, -0.3730807122324292, 0.6740106823161018, 0.8562214990564344, 0.955785083955732, 1.7020898014886303, 1.8523009430646802, 0.244 ... 3951759101545, -1.1611722313627828, 1.1602446901533021, 1.1052173095128992, 1.1089143920161917, -0.13837156328402}}, {{0, 100, 1}}, 2, {"Continuous", 2}, {"Discrete", 1}, 1, {ValueDimensions -> 1, ResamplingMethod -> None}}, False, 10.1];
Wolfram Language code: SignTest[td]

只检测所有值：

Wolfram Language code: data = td["ValueList"]//Flatten; SignTest[data]

检测两条路径中位数的差异：

Wolfram Language code: {data1, data2} = td["ValueList"];
Wolfram Language code: SignTest[{data1, data2}]

巧妙范例  (2)

当零假设 为真时，计算统计量：

Wolfram Language code: data1 = RandomVariate[NormalDistribution[], {2500, 100}]; data2 = RandomVariate[NormalDistribution[], {2500, 100}];
Wolfram Language code: T1 = MapThread[SignTest[{#1, #2}, 0, "TestStatistic"]&, {data1, data2}];

给定特定的备择假设的检验统计量：

Wolfram Language code: T2 = MapThread[SignTest[{#1, #2}, 1, "TestStatistic"]&, {data1, data2}];

比较检验统计量的分布：

Wolfram Language code: SmoothHistogram[{T1, T2}, Filling -> Axis, PlotLegends -> {"SubscriptBox[H, 0] is True", "SubscriptBox[H, 0] is False"}]

三维空间中，空间符号的分布表明：从零均值向量的较大偏离，通常产生更多的高度集中的空间符号和较大的符号统计量：

Wolfram Language code: SpatialSign[d_] := With[{norm = Norm[d]}, If[norm == 0, ConstantArray[0, Length[d]], d / norm]]
Wolfram Language code: data = Table[RandomVariate[MultinormalDistribution[{a, -.5a, a}, IdentityMatrix[3]], 500], {a, {0, 1, 2, 4}}];
Wolfram Language code: sPointPlot[data_] := Show[Graphics3D[{Directive[Yellow, Specularity[White, 20]], Sphere[{0, 0, 0}]}], ListPointPlot3D[SpatialSign /@ data, PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}], Boxed -> False, PlotLabel -> TextCell[SignTest[data, 0, "TestStatistic"], "Section"], Background -> GrayLevel[0]]
Wolfram Language code: GraphicsGrid[Partition[sPointPlot /@ data, 2]]
Wolfram Research (2010)，SignTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SignTest.html.

文本

Wolfram Research (2010)，SignTest，Wolfram 语言函数，https://reference.wolfram.com/language/ref/SignTest.html.

CMS

Wolfram 语言. 2010. "SignTest." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/SignTest.html.

APA

Wolfram 语言. (2010). SignTest. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/SignTest.html 年

BibTeX

@misc{reference.wolfram_2026_signtest, author="Wolfram Research", title="{SignTest}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/SignTest.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_signtest, organization={Wolfram Research}, title={SignTest}, year={2010}, url={https://reference.wolfram.com/language/ref/SignTest.html}, note=[Accessed: 11-September-2026]}