WOLFRAM

Wolfram 语言与系统参考资料中心

VertexColors

是图元的一个选项，指定分配给顶点的颜色.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
图形对象  
图形 3D 基元和形状  
颜色规格  
可视化功能  
可能存在的问题  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

VertexColors

VertexColors

是图元的一个选项，指定分配给顶点的颜色.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (3)

绘制多色形状：

Wolfram Language code: Graphics[Polygon[{{0, 0}, {0, 1}, {1, 1}, {1, 0}}, VertexColors -> {Blue, Green, Brown, Purple}]]

绘制多色三维形状：

Wolfram Language code: Graphics3D[{Polygon[{{0, 0, 0}, {1, 1, 0}, {0, 1, 1}}, VertexColors -> {Blue, Yellow, Orange}]}]

绘制多色线条：

Wolfram Language code: Graphics[{Thick, Line[{{0, 0}, {1, 1}, {2, 0}}, VertexColors -> {StandardRed, StandardYellow, StandardGreen}]}]

范围  (17)

图形对象  (5)

Polygon：

Wolfram Language code: Graphics[Polygon[{{-1, 0}, {1, 0}, {0, Sqrt[3]}}, VertexColors -> {Red, Green, Blue}]]

多个多边形：

Wolfram Language code: Graphics[Polygon[{{{-1, 0}, {1, 0}, {0, Sqrt[3]}}, {{2, 0}, {4, 0}, {3, Sqrt[3]}}}, VertexColors -> {{Red, Green, Blue}, {Yellow, Cyan, Magenta}}]]

Line：

Wolfram Language code: Graphics[{Thick, Line[{{0, 0}, {2, 1}}, VertexColors -> {Red, Green}]}]
Wolfram Language code: Graphics[{Thick, Line[{{{0, 0}, {2, 1}}, {{1, 0}, {3, 1}}}, VertexColors -> {{Red, Green}, {Yellow, Blue}}]}]

多个点：

Wolfram Language code: Graphics[{PointSize[0.1], Point[{{0, 0}, {1, 1}, {2, 2}}, VertexColors -> {StandardRed, StandardYellow, StandardBlue}]}]

Triangle：

Wolfram Language code: Graphics[{Triangle[{{0, 0}, {0, 1}, {1, 1}}, VertexColors -> {Red, Green, Blue}]}]

多个三角形：

Wolfram Language code: Graphics[{Triangle[{{{0, 0}, {0, 1}, {1, 1}}, {{2, 0}, {2, 1}, {3, 1}}}, VertexColors -> {{Red, Green, Blue}, {Yellow, Cyan, Magenta}}]}]

在 GraphicsComplex 中，可为共享顶点指定颜色：

Wolfram Language code: Graphics[{GraphicsComplex[{{0, 0}, {1, 0}, {0, 1}, {1, 1}, {.5, .5}}, {Polygon[{1, 2, 5}], Polygon[{3, 4, 5}]}, VertexColors -> {LightRed, DarkRed, LightBlue, DarkBlue, Purple}]}]

图形 3D 基元和形状  (5)

Polygon：

Wolfram Language code: Graphics3D[Polygon[{{0, -1, 0}, {0, 1, 0}, {-1, 0, 1}}, VertexColors -> {Red, Green, Blue}]]

多个多边形：

Wolfram Language code: Graphics3D[Polygon[{{{0, -1, 0}, {0, 1, 0}, {-1, 0, 1}}, {{0, -1, 1}, {0, 1, 1}, {-1, 0, 2}}}, VertexColors -> {{Red, Green, Blue}, {Cyan, Magenta, Yellow}}]]

Line：

Wolfram Language code: Graphics3D[{Thick, Line[{{0, 0, 0}, {1, 1, 1}, {2, 2, 1}}, VertexColors -> {Red, Green, Yellow}]}]

多条线：

Wolfram Language code: Graphics3D[{Thick, Line[{{{0, 0, 0}, {2, 1, 1}}, {{1, 0, 0}, {3, 1, 1}}}, VertexColors -> {{Red, Green}, {Blue, Yellow}}]}]

Tube：

Wolfram Language code: Graphics3D[{Tube[{{0, 0, 0}, {1, 1, 1}, {2, 2, 1}}, 0.1, VertexColors -> {Red, Green, Yellow}]}]

多管道：

Wolfram Language code: Graphics3D[{Tube[{{{0, 0, 0}, {2, 1, 1}}, {{1, 0, 0}, {3, 1, 1}}}, .2, VertexColors -> {{Red, Green}, {Blue, Yellow}}]}]

点：

Wolfram Language code: Graphics3D[{PointSize[0.1], Point[{{0, 0, 0}, {1, 1, 1}, {2, 1, 0}}, VertexColors -> {StandardRed, StandardGreen, StandardOrange}]}, PlotRangePadding -> .1]

在 GraphicsComplex 中，可为共享顶点指定颜色：

Wolfram Language code: v = {{0, 0, 0}, {2, 0, 0}, {2, 2, 0}, {0, 2, 0}, {1, 1, 2}};
Wolfram Language code: i = {{1, 2, 5}, {2, 3, 5}, {3, 4, 5}, {4, 1, 5}};
Wolfram Language code: Graphics3D[{GraphicsComplex[v, Polygon[i], VertexColors -> {Red, Green, Yellow, Blue, Opacity[.8, White]}]}]

颜色规格  (5)

颜色指令可包含不同的不透明度值：

Wolfram Language code: Graphics3D[Polygon[{{0, -1, 0}, {0, 1, 0}, {-1, 0, 1}}, VertexColors -> {RGBColor[0, 1, 0, .1], RGBColor[0, 1, 0, .4], RGBColor[0, 1, 0, .9]}]]

可使用 Directive 将颜色与 Opacity 组合：

Wolfram Language code: Graphics3D[Polygon[{{0, -1, 0}, {0, 1, 0}, {-1, 0, 1}}, VertexColors -> {Red, Green, Directive[Blue, Opacity[.5]]}]]

可混合使用不同色彩空间对应的颜色指令：

Wolfram Language code: Graphics[Polygon[{{0, -1}, {0, 1}, {-1, 0}}, VertexColors -> {RGBColor[0, 1, 0], GrayLevel[.2], LABColor[.6, .5, 1]}]]

可使用 LightDarkSwitched 规格配置：

Wolfram Language code: g = Graphics[{Thickness[.1], Line[{{0, 0}, {1, 1}}, VertexColors -> {LightDarkSwitched[LightRed, LightBlue], LightDarkSwitched[DarkRed, DarkBlue]}]}]; {Rasterize[g, LightDark -> "Light"], Rasterize[g, LightDark -> "Dark"]}

使用原始数值列表直接指定 {red,green,blue} ，而非通过 RGBColor 函数指定：

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {0, 1}, {2, 0}}, VertexColors -> {{1, 0, 0}, {0, 1, 0}, {0, 0, 1}}]}]

类似地，指定 {red,green,blue,opacity}：

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {0, 1}, {2, 0}}, VertexColors -> {{1, 0, 0, .1}, {0, 1, 0.9}, {0, 0, 1, .5}}]}]

指定灰度等级时请使用 {gray1,gray2,…}：

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {0, 1}, {2, 0}}, VertexColors -> {.1, .9, .4}]}]

带不透明度的灰度等级应指定为 {gray,opacity}：

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {0, 1}, {2, 0}}, VertexColors -> {{.5, 0}, {.5, 1}, {.5, .5}}]}]

可视化功能  (2)

ListPlot3D：

Wolfram Language code: ListPlot3D[{{0, 0, 1}, {1, 0, 0}, {0, 1, 0}}, VertexColors -> {Red, Green, Blue}, Lighting -> "Neutral"]

ListDensityPlot：

Wolfram Language code: ListDensityPlot[{{0, 0, 1}, {1, 0, 0}, {0, 1, 0}}, VertexColors -> {Red, Green, Blue}]

可能存在的问题  (2)

在 FilledCurve 的分段内指定的顶点颜色将被忽略：

Wolfram Language code: Graphics[{EdgeForm[Thick], Pink, FilledCurve[Line[{{0, 0}, {1, 0}, {1, 1}, {0, 1}}, VertexColors -> {Red, Green, Blue, Yellow}]]}]

VertexColors 列表过短时，剩余点将使用默认颜色：

Wolfram Language code: Graphics[{Polygon[{{0, 0}, {1, 1}, {2, 0}}, VertexColors -> {StandardOrange, StandardBlue}]}]

若默认图元颜色已通过指令修改，则使用修改后的颜色：

Wolfram Language code: Graphics[{StandardPurple, Polygon[{{0, 0}, {1, 1}, {2, 0}}, VertexColors -> {StandardOrange, StandardBlue}]}]

巧妙范例  (2)

在三维多边形中设置不透明度条件：

Wolfram Language code: PolyhedronData["GreatRhombicosidodecahedron"] /. Polygon[x_] :> Polygon[x, VertexColors -> Map[Opacity[If[EvenQ[#], 0, 1], White]&, x, {-1}]]

采用 ExampleData 中一个图形示例：

Wolfram Language code: pic = Reverse[ExampleData[{"TestImage", "Sailboat"}, "Data"] / 255.];

用有颜色的顶点绘制数据集合，模拟纹理：

Wolfram Language code: ListPlot3D[Table[x + Sin[x y], {x, -5, 5, .1}, {y, -5, 5, .1}], Mesh -> None, VertexColors -> {pic[[5 ;; -5 ;; 5, 5 ;; -5 ;; 5]]}, Lighting -> "Neutral"]
Wolfram Research (2007)，VertexColors，Wolfram 语言函数，https://reference.wolfram.com/language/ref/VertexColors.html （更新于 2008 年）.

文本

Wolfram Research (2007)，VertexColors，Wolfram 语言函数，https://reference.wolfram.com/language/ref/VertexColors.html （更新于 2008 年）.

CMS

Wolfram 语言. 2007. "VertexColors." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2008. https://reference.wolfram.com/language/ref/VertexColors.html.

APA

Wolfram 语言. (2007). VertexColors. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/VertexColors.html 年

BibTeX

@misc{reference.wolfram_2026_vertexcolors, author="Wolfram Research", title="{VertexColors}", year="2008", howpublished="\url{https://reference.wolfram.com/language/ref/VertexColors.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_vertexcolors, organization={Wolfram Research}, title={VertexColors}, year={2008}, url={https://reference.wolfram.com/language/ref/VertexColors.html}, note=[Accessed: 11-September-2026]}