WOLFRAM

Wolfram 语言与系统参考资料中心

ConicHullRegion[{p1,…,pm+1}]

表示通过点 pi 的 m 维仿射壳体区域.

ConicHullRegion[p,{v1,…,vm}]

表示通过点 p 并与 vi 平行的 m 维仿射壳体区域.

ConicHullRegion[{p1,…,pm+1},{w1,…,wn}]

表示 m 维仿射壳体加上由向量 wj 生成的锥形壳体.

ConicHullRegion[p,{v1,…,vm},{w1,…,wn}]

表示 m 维仿射壳体加上由向量 wj 生成的锥形壳体.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式化  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

ConicHullRegion

ConicHullRegion[{p1,…,pm+1}]

表示通过点 pi 的 m 维仿射壳体区域.

ConicHullRegion[p,{v1,…,vm}]

表示通过点 p 并与 vi 平行的 m 维仿射壳体区域.

ConicHullRegion[{p1,…,pm+1},{w1,…,wn}]

表示 m 维仿射壳体加上由向量 wj 生成的锥形壳体.

ConicHullRegion[p,{v1,…,vm},{w1,…,wn}]

表示 m 维仿射壳体加上由向量 wj 生成的锥形壳体.

更多信息

  • ConicHullRegion 也被称作仿射空间、半空间和特殊情况下的仿射壳体.
  • ConicHullRegion 可被用作几何区域和图形基元.
  • 情况 ConicHullRegion[{p1,…,pm+1}] 和 ConicHullRegion[p,{v1,…,vm}] 表示仿射壳体，通常称作无限直线、 无限平面或无限空间.
  • 锥形方向 wj 表示纯锥形壳体 ，被添加到仿射壳体中的每个点，也被称作仿射壳体和锥形壳体的闵可夫斯基（Minkowski）和.
  • 参数表示由以下形式给出：
  • ConicHullRegion[{p1,…,pm+1}]
    ConicHullRegion[p,{v1,…,vm}]
    ConicHullRegion[{p1,…,pm+1},{w1,…,wn}]
    ConicHullRegion[p,{v1,…,vm},{w1,…,wn}]
  • ConicHullRegion 的低维版本具有特殊表示：
  • ConicHullRegion[{p1,p2}]InfiniteLine[{p1,p2}]
    ConicHullRegion[{p1,p2,p3}]InfinitePlane[{p1,p2,p3}]
    ConicHullRegion[{p1},{w1}]HalfLine[p1,w1]
    ConicHullRegion[{p1,p2},{w1}]HalfPlane[{p1,p2},w1]
  • 如果 vi 线性独立，ConicHullRegion[p,{v1,…,vm}] 表示 m 维区域.
  • ConicHullRegion 可用于 Graphics 和 Graphics3D.
  • 在图形中，点 p、pi 和向量 vi、wj 可以是 Dynamic 表达式.
  • 图形渲染受诸如 FaceForm、EdgeForm、Opacity 和颜色等指令的影响

范例

打开所有单元 关闭所有单元

基本范例  (3)

在二维中的 ConicHullRegion：

Wolfram Language code: Graphics[ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 1}}]]

在三维中：

Wolfram Language code: Graphics3D[ConicHullRegion[{{0, 0, 0}}, {{-10, 2, 3}, {1, 1, 0}}]]

应用于锥形壳体区域的不同样式：

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 1}}];
Wolfram Language code: {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

确定点是否属于给定的锥形壳体区域：

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 1}}];
Wolfram Language code: {RegionMember[ℛ, {1, 0}], RegionMember[ℛ, {-1, 0}]}

范围  (25)

图形  (15)

规范  (7)

定义一条通过 {1,1} 和 {3,2} 的无限直线：

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{1, 1}, {3, 2}}]}, PlotRange -> {{0, 4}, {0, 3}}, Frame -> True];
Wolfram Language code: Show[ill, Graphics[ConicHullRegion[{{1, 1}, {3, 2}}]]]

定义通过 {1,1} 沿方向 {2,1} 的相同直线：

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{1, 1}}], Arrowheads[Medium], Thick, Arrow[{{1, 1}, {3, 2}}]}, PlotRange -> {{0, 4}, {0, 3}}, Frame -> True];
Wolfram Language code: Show[ill, Graphics[ConicHullRegion[{1, 1}, {{2, 1}}]]]

使用一个点、一个向量和一个锥形方向定义上半平面：

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{0, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0}, {1, 0}}], Arrow[{{0, 0}, {0, 1}}]}];
Wolfram Language code: Show[Graphics[{Pink, ConicHullRegion[{0, 0}, {{1, 0}}, {{0, 1}}]}, PlotRange -> {{-1, 2}, {-1, 2}}, Frame -> True], ill]

或者使用一个点和两个锥形方向定义二维无限空间：

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{0, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0}, {1, 1}}], Arrow[{{0, 0}, {-1, 1}}]}];
Wolfram Language code: Show[Graphics[{Pink, ConicHullRegion[{{0, 0}}, {{1, 1}, {-1, 1}}]}, PlotRange -> {{-2, 2}, {-1, 2}}, Frame -> True], ill]

定义在三维中通过点 和 的无限直线：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{1, 1, 1}, {2, 3, 4}}]}, PlotRange -> 5, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[ConicHullRegion[{{1, 1, 1}, {2, 3, 4}}]]]

使用点 和一个方向向量定义同一直线：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{1, 1, 1}}], Arrowheads[Medium], Thick, Arrow[{{1, 1, 1}, {2, 3, 4}}]}, PlotRange -> 5, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[ConicHullRegion[{1, 1, 1}, {{1, 2, 3}}]]]

定义通过点 、 和 的平面：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{0, 1, 3}, {1, 0, 1}, {1, 2, 3}}]}, PlotRange -> {{-1, 2}, {-1, 3}, {0, 4}}, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[{Opacity[0.5], ConicHullRegion[{{0, 1, 3}, {1, 0, 1}, {1, 2, 3}}]}]]

使用点和方向向量定义同一平面：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{0, 1, 3}}], Arrowheads[Medium], Thick, Arrow[{{0, 1, 3}, {1, 0, 1}}], Arrow[{{0, 1, 3}, {1, 2, 3}}]}, PlotRange -> {{-1, 2}, {-1, 3}, {0, 4}}, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[{Opacity[0.5], ConicHullRegion[{0, 1, 3}, {{1, -1, -2}, {1, 1, 0}}]}]]

定义顶点为 且方向为 和 的二维无限锥：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{0, 0, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0, 0}, {0, 1, 2}}], Arrow[{{0, 0, 0}, {1, 2, 0}}]}, PlotRange -> {{-1, 3}, {-1, 3}, {-1, 3}}, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[ConicHullRegion[{{0, 0, 0}}, {{0, 1, 2}, {1, 2, 0}}]]]

三维半空间可用一个点、两个向量和一个锥形方向定义：

Wolfram Language code: Graphics3D[ConicHullRegion[{0, 0, 0}, {{1, 0, 0}, {0, 1, 0}}, {{0, 0, 1}}]]

三维无限空间可用一个点和多个锥形方向定义：

Wolfram Language code: Graphics3D[ConicHullRegion[{{0, 0, 0}}, {{1, 1, 0}, {0, 1, 1}, {1, 0, 1}}]]

样式化  (7)

具有不同粗细度的一维锥形壳体区域：

Wolfram Language code: Table[Graphics[{Thickness[i], ConicHullRegion[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{t, ConicHullRegion[{{0, 0}, {2, 1}}]}], {t, {Thin, Thick}}]

经尺寸缩放的粗细度：

Wolfram Language code: Table[Graphics[{Thickness[i], ConicHullRegion[{{0, 0}, {2, 1}}]}], {i, {.005, .05, .1}}]

以打印机点数定义的粗细度：

Wolfram Language code: Table[Graphics[{AbsoluteThickness[i], ConicHullRegion[{{0, 0}, {2, 1}}]}], {i, {1, 5, 10}}]

一维锥形壳体区域可渲染为点化线或虚线：

Wolfram Language code: Table[Graphics[{Dashing[i], ConicHullRegion[{{0, 0}, {2, 1}}]}], {i, {Tiny, Small, Medium, Large}}]
Wolfram Language code: Table[Graphics[{d, ConicHullRegion[{{0, 0}, {2, 1}}]}], {d, {Dotted, Dashed, DotDashed}}]

颜色指令指定一维锥形壳体区域的边缘颜色：

Wolfram Language code: Table[Graphics[{c, ConicHullRegion[{{0, 0}, {2, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

颜色指令指定高维区域的表面颜色：

Wolfram Language code: Table[Graphics[{c, ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 2}}]}], {c, {Red, Green, Blue, Yellow}}]
Wolfram Language code: Table[Graphics3D[{c, ConicHullRegion[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可用于指定表面和边的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], ConicHullRegion[{{0, 0}}, {{1, -1}, {1, 2}}]}]
Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], ConicHullRegion[{{1, 0, 0}, {1, 1, 1}, {0, 0, 1}}]}]

在三维中，可使用 FaceForm 指定正面和背面的不同属性：

Wolfram Language code: p = {FaceForm[Yellow, Blue], ConicHullRegion[{{0, 0, 0}}, {{1, -1, 0}, {1, 2, 0}}]};
Wolfram Language code: {Graphics3D[p, ViewPoint -> Top], Graphics3D[p, ViewPoint -> Bottom]}

坐标  (1)

Scaled 坐标可用于二维：

Wolfram Language code: Graphics[ConicHullRegion[Scaled[{0, 0}], {Scaled[{1, 1}]}], Frame -> True]

和三维：

Wolfram Language code: Graphics3D[ConicHullRegion[Scaled[{0, 0, 0}], {Scaled[{1, 1, 0}], Scaled[{0, 1, 1}]}]]

区域  (10)

嵌入维是 ConicHullRegion 所在的维度：

Wolfram Language code: line = ConicHullRegion[{0, 0}, {{1, 1}}]; hplane = ConicHullRegion[{0, 0}, {{1, 1}}, {{1, 0}}];
Wolfram Language code: RegionEmbeddingDimension /@ {line, hplane}

几何维度是区域自身的维度：

Wolfram Language code: RegionDimension /@ {line, hplane}

点成员检验：

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0, 0}, {1, 1, 1}}];
Wolfram Language code: {RegionMember[ℛ, {2, 2, 2}], RegionMember[ℛ, {2, 2, 3}]}

获取点成员条件：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

ConicHullRegion 具有无限尺寸：

Wolfram Language code: ℛ = ConicHullRegion[{{1, 2}, {3, 4}}];
Wolfram Language code: RegionMeasure[ℛ]

和不确定质心：

Wolfram Language code: RegionCentroid[ℛ]

距一个点的距离：

Wolfram Language code: ℛ = ConicHullRegion[{{2, 2}}, {{3, 1}, {1, 3}}];
Wolfram Language code: RegionDistance[ℛ, {0, 1}]

到最近点的距离：

Wolfram Language code: {Plot3D[Evaluate@RegionDistance[ℛ, {x, y}], {x, 1, 3}, {y, 1, 3}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> None], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, 0, 4}, {y, 0, 4}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}, Exclusions -> None]}

距一个点的带符号距离：

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0}, {1, 0}}, {{0, 1}}];
Wolfram Language code: SignedRegionDistance[ℛ, {2, 3}]

区域中的最近点：

Wolfram Language code: ℛ = ConicHullRegion[{{2, 2}, {3, 3}}];
Wolfram Language code: RegionNearest[ℛ, {5, 6}]

对其可视化：

Wolfram Language code: pts = Table[{1, 2} + 5{Cos[k 2 π / 16], Sin[k 2π / 16]}, {k, 0., 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Thick, Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

锥形壳体区域是无界的：

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0, 0}, {1, 0, 0}}, {{0, 1, 0}}];
Wolfram Language code: BoundedRegionQ[ℛ]

但可能不是在所有方向都无界：

Wolfram Language code: RegionBounds[ℛ]

在 ConicHullRegion 上进行 Integrate：

Wolfram Language code: ℛ = ConicHullRegion[{0, 0}, {{1, 0}, {0, 1}}];
Wolfram Language code: Integrate[Exp[-(x^2 + y^2)], {x, y}∈ℛ]

进行最优化：

Wolfram Language code: ℛ = ConicHullRegion[{{0, 1}, {1, 0}}, {{1, 1}}];
Wolfram Language code: Maximize[{-(x^2 + y^2), {x, y}∈ℛ}, {x, y}]

在锥形壳体上解方程：

Wolfram Language code: ℛ = ConicHullRegion[{{0, 0}}, {{0, 1}, {1 / 2, 1 / 2}}];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

应用  (4)

定义一个占据每个象限的区域：

Wolfram Language code: rl = Flatten[Table[ConicHullRegion[{{0, 0}}, {{x, 0}, {0, y}}], {x, {-1, 1}}, {y, {-1, 1}}]]
Wolfram Language code: Table[Graphics[{StandardBlue, r}, Axes -> True], {r, rl}]

定义一个占据每个卦限的区域：

Wolfram Language code: rl = Flatten[Table[ConicHullRegion[{{0, 0, 0}}, {{x, 0, 0}, {0, y, 0}, {0, 0, z}}], {x, {-1, 1}}, {y, {-1, 1}}, {z, {-1, 1}}]];
Wolfram Language code: Graphics3D /@ rl

从中心点和圆周上的点构建一个锥形壳体区域：

Wolfram Language code: rl = Table[ConicHullRegion[{{0, 0, -1}}, Table[{Cos[k 2π / n], Sin[k 2π / n], 1}, {k, 0., n - 1}]], {n, 3, 12, 3}];
Wolfram Language code: Table[Graphics3D[{Opacity[0.5], Yellow, r}, PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}], {r, rl}]

从中心点和参数曲线上的点构建一个锥形壳体区域：

Wolfram Language code: o = {0, 0, 0}; f[t_] := {16Sin[t] ^ 3, 13Cos[t] - 5Cos[2t] - 2Cos[3t] - Cos[4t], 16}; pts = Table[f[t], {t, 0, 2π, 0.1}];
Wolfram Language code: chr = ConicHullRegion[{o}, pts]; Graphics3D[chr, PlotRange -> {{-16, 16}, {-17, 12}, {0, 16}}]

属性和关系  (5)

InfiniteLine 是 ConicHullRegion 的特殊情形：

Wolfram Language code: pl = {{1, 2}, {3, 4}};
Wolfram Language code: Reduce[{x, y}∈ConicHullRegion[pl]⧦{x, y}∈InfiniteLine[pl], {x, y}, Reals]

HalfLine 是 ConicHullRegion 的特殊情形：

Wolfram Language code: Subscript[ℛ, 1] = ConicHullRegion[{{0, 0}}, {{1, 1}}]; Subscript[ℛ, 2] = HalfLine[{0, 0}, {1, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

InfinitePlane 是 ConicHullRegion 的特殊情形：

Wolfram Language code: Subscript[ℛ, 1] = ConicHullRegion[{0, 0, 0}, {{1, 0, 0}, {0, 1, 0}}]; Subscript[ℛ, 2] = InfinitePlane[{0, 0, 0}, {{1, 0, 0}, {0, 1, 0}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

HalfPlane 是 ConicHullRegion 的特殊情形：

Wolfram Language code: Subscript[ℛ, 1] = ConicHullRegion[{{0, 0}, {1, 0}}, {{0, 1}}]; Subscript[ℛ, 2] = HalfPlane[{{0, 0}, {1, 0}}, {0, 1}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion 可以表示任何 ConicHullRegion：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[-1 - x + y == 0, {x, y}];
Wolfram Language code: Subscript[ℛ, 2] = ConicHullRegion[{{1, 2}, {3, 4}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (1)

一个随机仿射锥体的集合：

Wolfram Language code: Graphics[{EdgeForm[Black], Table[{Hue[RandomReal[]], Opacity[0.1], ConicHullRegion[{RandomReal[1, 2]}, RandomReal[{-1, 1}, {2, 2}]]}, {75}]}]
Wolfram Research (2014)，ConicHullRegion，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConicHullRegion.html.

文本

Wolfram Research (2014)，ConicHullRegion，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ConicHullRegion.html.

CMS

Wolfram 语言. 2014. "ConicHullRegion." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/ConicHullRegion.html.

APA

Wolfram 语言. (2014). ConicHullRegion. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ConicHullRegion.html 年

BibTeX

@misc{reference.wolfram_2026_conichullregion, author="Wolfram Research", title="{ConicHullRegion}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ConicHullRegion.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_conichullregion, organization={Wolfram Research}, title={ConicHullRegion}, year={2014}, url={https://reference.wolfram.com/language/ref/ConicHullRegion.html}, note=[Accessed: 12-September-2026]}