WOLFRAM

Wolfram 语言与系统参考资料中心

HalfPlane[{p1,p2},w]

表示由经过 p1 和 p2 两点的直线界定的并且向 w 方向延伸的半平面.

HalfPlane[p,v,w]

表示由经过 p 点、走向为 v 的直线界定的并且向 w 方向延伸的半平面.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式  
坐标  
区域  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

HalfPlane

HalfPlane[{p1,p2},w]

表示由经过 p1 和 p2 两点的直线界定的并且向 w 方向延伸的半平面.

HalfPlane[p,v,w]

表示由经过 p 点、走向为 v 的直线界定的并且向 w 方向延伸的半平面.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (4)

二维 HalfPlane：

Wolfram Language code: Graphics[HalfPlane[{{0, 0}, {1, 0}}, {0, 1}], Frame -> True]

以及三维：

Wolfram Language code: Graphics3D[HalfPlane[{{0, 0, 0}, {1, 0, 0}}, {0, 1, 1}]]

半平面的几种不同样式：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, -1}, {1, 1}];
Wolfram Language code: {Graphics[{Pink, ℛ}], Graphics[{EdgeForm[Thick], Pink, ℛ}], Graphics[{EdgeForm[Dashed], Pink, ℛ}], Graphics[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

半平面的面积 Area 为无穷大：

Wolfram Language code: Area[HalfPlane[{{0, 0}, {1, 0}}, {0, 1}]]

确定某点是否属于给定半平面：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: {RegionMember[ℛ, {1, 1}], RegionMember[ℛ, {1, -1}]}

范围  (18)

图形  (8)

规范  (3)

用一个点和两个矢量定义上半平面：

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{0, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0}, {1, 0}}], Arrow[{{0, 0}, {0, 1}}]}];
Wolfram Language code: Show[Graphics[{Pink, HalfPlane[{0, 0}, {1, 0}, {0, 1}]}, PlotRange -> {{-1, 2}, {-1, 2}}, Frame -> True], ill]

或者用两个点和一个矢量：

Wolfram Language code: ill = Graphics[{PointSize[Medium], Point[{{0, 0}, {1, 0}}], Arrowheads[Medium], Thick, Arrow[{{0, 0}, {0, 1}}]}];
Wolfram Language code: Show[Graphics[{Pink, HalfPlane[{{0, 0}, {1, 0}}, {0, 1}]}, PlotRange -> {{-1, 2}, {-1, 2}}, Frame -> True], ill]

用一个点和两个矢量定义一个三维空间的半平面：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{0, 1, 3}}], Arrowheads[Medium], Thick, Arrow[{{0, 1, 3}, {1, 0, 1}}], Arrow[{{0, 1, 3}, {1, 2, 3}}]}, PlotRange -> {{-1, 2}, {-1, 3}, {0, 4}}, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[HalfPlane[{0, 1, 3}, {1, -1, -2}, {1, 1, 0}]]]

或者用两个点和一个矢量：

Wolfram Language code: ill = Graphics3D[{PointSize[Medium], Point[{{0, 1, 3}, {1, 0, 1}}], Arrowheads[Medium], Thick, Arrow[{{0, 1, 3}, {1, 2, 3}}]}, PlotRange -> {{-1, 2}, {-1, 3}, {0, 4}}, Axes -> True];
Wolfram Language code: Show[ill, Graphics3D[HalfPlane[{{0, 1, 3}, {1, 0, 1}}, {1, 1, 0}]]]

由符号参数定义的半平面：

Wolfram Language code: Table[Graphics[HalfPlane[{0, 0}, {Cos[θ], Sin[θ]}, {Sin[θ], -Cos[θ]}], ImageSize -> Tiny, PlotLabel -> θ], {θ, 0, π, π / 4}]

样式  (2)

着色指令可指定半平面的颜色：

Wolfram Language code: Table[Graphics[{c, HalfPlane[{0, 0}, {1, 1}, {0, 1}]}], {c, {Red, Green, Blue, Yellow}}]
Wolfram Language code: Table[Graphics3D[{c, HalfPlane[{0, 1, 3}, {1, -1, -2}, {1, 1, 0}]}, PlotRange -> {{-1, 2}, {-1, 3}, {0, 4}}], {c, {Red, Green, Blue, Yellow}}]

FaceForm 和 EdgeForm 可被用来指定面和边的样式：

Wolfram Language code: Graphics[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], HalfPlane[{0, 0}, {1, 1}, {0, 1}]}]
Wolfram Language code: Graphics3D[{FaceForm[Pink], EdgeForm[Directive[Dashed, Thick, Blue]], HalfPlane[{0, 1, 3}, {1, -1, -2}, {1, 1, 0}]}, PlotRange -> {{-1, 2}, {-1, 3}, {0, 4}}]

坐标  (3)

指定绘图范围来确定坐标：

Wolfram Language code: Graphics[HalfPlane[{Scaled[{0, 0.25}], Scaled[{1, 0.5}]}, Scaled[{0, 1}]], PlotRange -> {{0, 10}, {0, 10}}, Frame -> True]
Wolfram Language code: Graphics3D[HalfPlane[{Scaled[{0, 0.25, 0}], Scaled[{1, 0.5, 1}]}, Scaled[{0, 1, 1}]], PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

在二维中指定一般坐标的缩放偏移量：

Wolfram Language code: Graphics[HalfPlane[{Scaled[{0, 0.5}, {2, 0}], Scaled[{0, 0.5}, {1, 2}]}, Scaled[{0, 1}]], PlotRange -> {{0, 4}, {0, 4}}, Frame -> True]

点和矢量可以是 Dynamic：

Wolfram Language code: DynamicModule[{θ = 0}, {Slider[Dynamic[θ], {0, Pi}], Graphics[HalfPlane[{{0, 0}, Dynamic[{Cos[θ], Sin[θ]}]}, {1, 1}]]}]

区域  (10)

嵌入维度是坐标的维度：

Wolfram Language code: RegionEmbeddingDimension[HalfPlane[{0, 0}, {1, 0}, {0, 1}]]
Wolfram Language code: RegionEmbeddingDimension[HalfPlane[{0, 0, 0}, {1, 0, 0}, {1, 1, 0}]]

几何维度是区域自身的维度：

Wolfram Language code: RegionDimension[HalfPlane[{0, 0}, {1, 0}, {1, 1}]]

判断是否为成员：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: {RegionMember[ℛ, {1, 5}], RegionMember[ℛ, {1, -5}]}

获取成为该区域成员的条件：

Wolfram Language code: RegionMember[ℛ, {x, y}]

半平面的度量为无穷大，无法定义几何中心：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: RegionMeasure[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

从一个点到半平面的距离：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: RegionDistance[ℛ, {2, -3}]

将其可视化：

Wolfram Language code: {Plot3D[RegionDistance[ℛ, {x, y}], {x, -1, 1}, {y, -1, 1}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> y == 0], ContourPlot[Evaluate@RegionDistance[ℛ, {x, y}], {x, -2, 2}, {y, -2, 2}, Contours -> {{0.5, Red}, {1, Green}, {1.5, Blue}}]}

到半平面的符号距离：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: {SignedRegionDistance[ℛ, {2, -3}], SignedRegionDistance[ℛ, {2, 3}]}

画出图形：

Wolfram Language code: Plot3D[SignedRegionDistance[ℛ, {x, y}], {x, -1, 1}, {y, -1, 1}, MeshFunctions -> {#3&}, Mesh -> 5, Exclusions -> y == 0]

最近的点：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, -1}, {1, 1}];
Wolfram Language code: RegionNearest[ℛ, {2, -3}]

将其可视化：

Wolfram Language code: pts = Table[{Cos[k 2 π / 16], Sin[k 2 π / 16]}, {k, 0, 15}]; nst = RegionNearest[ℛ, #]& /@ pts;
Wolfram Language code: Legended[Graphics[{{Gray, ℛ}, {Thin, Gray, Line[Transpose[{pts, nst}]]}, {Red, Point[pts]}, {Blue, Point[nst]}}], PointLegend[{Red, Blue}, {"start", "nearest"}]]

半平面是无界的：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: BoundedRegionQ[ℛ]

找出区域范围：

Wolfram Language code: RegionBounds[ℛ]

在半平面上积分：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: Integrate[Exp[-x^2 - y^2], {x, y}∈ℛ]

在半平面上最优化：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: Minimize[{(x - 1 / 2)^2(y - 1 / 4)^2 + 1, {x, y}∈ℛ}, {x, y}]

在半平面上求解方程：

Wolfram Language code: ℛ = HalfPlane[{0, 0}, {1, 0}, {0, 1}];
Wolfram Language code: Reduce[x^2 + y^2 == 1 && {x, y}∈ℛ, {x, y}]

应用  (3)

定义占两个相邻象限的区域：

Wolfram Language code: hpl = {HalfPlane[{{0, 0}, {1, 0}}, {0, 1}], HalfPlane[{{0, 0}, {1, 0}}, {0, -1}], HalfPlane[{{0, 0}, {0, 1}}, {1, 0}], HalfPlane[{{0, 0}, {0, 1}}, {-1, 0}]};
Wolfram Language code: Graphics[{Opacity@0.3, #}, Axes -> True]& /@ hpl

在 BubbleChart 中划分空间：

Wolfram Language code: b = BubbleChart3D[RandomReal[1, {20, 4}]];
Wolfram Language code: hpl = Table[HalfPlane[{0.5, 0, 0.5}, {0, 0.5, 0}, w], {w, {{0, 0, -1}, {-1, 0, 1}, {1, 0, 1}}}];

合并图形：

Wolfram Language code: Show[b, Graphics3D[{Opacity@0.6, hpl}]]

找出球面、半平面和平面 的相交点：

Wolfram Language code: Subscript[ℛ, 1] = Sphere[]; Subscript[ℛ, 2] = HalfPlane[{0, 0, 0}, {0, 1, 0}, {1, 0, 1}];
Wolfram Language code: pts = Solve[2 x y == z^2 && {x, y, z}∈Subscript[ℛ, 1] && {x, y, z}∈Subscript[ℛ, 2], {x, y, z}, Reals]

可视化相交点：

Wolfram Language code: intersections = {PointSize[Large], Red, Point[{x, y, z} /. pts]};
Wolfram Language code: r1 = {Opacity[0.5, LightBlue], Subscript[ℛ, 1]};
Wolfram Language code: r2 = {Opacity[0.5, Yellow], Subscript[ℛ, 2]};
Wolfram Language code: r3 = ContourPlot3D[2 x y == z^2, {x, -1.2, 1.2}, {y, -1.2, 1.2}, {z, -1.2, 1.2}, Mesh -> None, ContourStyle -> Opacity[0.5]];
Wolfram Language code: Show[{Graphics3D[{r1, r2, intersections}], r3}, Boxed -> False]

属性和关系  (4)

可以用 ConicHullRegion 来表示任意 HalfPlane：

Wolfram Language code: Subscript[ℛ, 1] = HalfPlane[{{0, 1, 3}, {1, 0, 1}}, {1, 1, 0}];
Wolfram Language code: Subscript[ℛ, 2] = ConicHullRegion[{{0, 1, 3}, {1, 0, 1}}, {{1, 1, 0}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ImplicitRegion 可用来表示任意 HalfPlane：

Wolfram Language code: Subscript[ℛ, 1] = HalfPlane[{1, 1}, {1, 2}, {2, -1}];
Wolfram Language code: Subscript[ℛ, 2] = ImplicitRegion[1 - 2x + y ≤ 0, {x, y}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

ParametricRegion 可用来表示任意 HalfPlane：

Wolfram Language code: Subscript[ℛ, 1] = HalfPlane[{1, 1}, {1, 2}, {2, -1}];
Wolfram Language code: Subscript[ℛ, 2] = ParametricRegion[{1, 1} + u{1, 2} + v{2, -1}, {{u, -∞, ∞}, {v, 0, ∞}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

任何 InfinitePlane 都可被表示为两个半平面的并集：

Wolfram Language code: Subscript[ℛ, 1] = InfinitePlane[{0, 1, 3}, {{1, -1, -2}, {1, 1, 0}}];
Wolfram Language code: Subscript[ℛ, 2] = RegionUnion[HalfPlane[{0, 1, 3}, {1, -1, -2}, {1, 1, 0}], HalfPlane[{0, 1, 3}, {1, -1, -2}, {-1, -1, 0}]];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (1)

随意排列的半平面：

Wolfram Language code: Graphics3D[Table[{Hue[RandomReal[]], Opacity[0.3], HalfPlane[RandomReal[1, {2, 3}], RandomReal[{-1, 1}, 3]]}, {15}], PlotRange -> {{-1, 1}, {-1, 1}, {-1, 1}}]
Wolfram Research (2014)，HalfPlane，Wolfram 语言函数，https://reference.wolfram.com/language/ref/HalfPlane.html （更新于 2016 年）.

文本

Wolfram Research (2014)，HalfPlane，Wolfram 语言函数，https://reference.wolfram.com/language/ref/HalfPlane.html （更新于 2016 年）.

CMS

Wolfram 语言. 2014. "HalfPlane." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2016. https://reference.wolfram.com/language/ref/HalfPlane.html.

APA

Wolfram 语言. (2014). HalfPlane. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/HalfPlane.html 年

BibTeX

@misc{reference.wolfram_2026_halfplane, author="Wolfram Research", title="{HalfPlane}", year="2016", howpublished="\url{https://reference.wolfram.com/language/ref/HalfPlane.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_halfplane, organization={Wolfram Research}, title={HalfPlane}, year={2016}, url={https://reference.wolfram.com/language/ref/HalfPlane.html}, note=[Accessed: 11-September-2026]}