WOLFRAM

Wolfram 语言与系统参考资料中心

Prism[{p1,…,p6}]

表示一个连接三角形 {p1,p2,p3} 和三角形 {p4,p5,p6} 的填充三棱柱.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式  
坐标  
区域  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Prism

Prism[{p1,…,p6}]

表示一个连接三角形 {p1,p2,p3} 和三角形 {p4,p5,p6} 的填充三棱柱.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

三棱柱：

Wolfram Language code: Graphics3D[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]

三棱柱的不同样式：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: Graphics3D[{EdgeForm[{Thick, Dashed, Blue}], FaceForm[{Pink, Opacity[0.7]}], ℛ}, Boxed -> False]
Wolfram Language code: {Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], ℛ}], Graphics3D[{EdgeForm[Dashed], ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

体积和几何中心：

Wolfram Language code: Volume[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]
Wolfram Language code: RegionCentroid[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]

范围  (18)

图形  (8)

规范  (2)

单个三棱柱：

Wolfram Language code: Graphics3D[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]

多个三棱柱：

Wolfram Language code: v1 = {{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}; v2 = v1 + 2;
Wolfram Language code: Graphics3D[Prism[{v1, v2}]]

样式  (3)

FaceForm 和 EdgeForm 可用来指定面和边的样式：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: Graphics3D[{EdgeForm[{Thick, Dashed, Blue}], FaceForm[{Pink, Opacity[0.7]}], ℛ}, Boxed -> False]

设置面的 Texture：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}, VertexTextureCoordinates -> {{0, 0}, {1, 1}, {1, 0}, {1, 1}, {1, 0}, {0, 1}}];
Wolfram Language code: Graphics3D[{Texture[[image]], ℛ}, Lighting -> "Neutral"]

为顶点分配 VertexColors：

Wolfram Language code: Graphics3D[Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}, VertexColors -> ColorData[60, "ColorList"]]]

坐标  (3)

用绘图范围的比例来指定坐标：

Wolfram Language code: ℛ = Prism[{Scaled[{0.5, 0., 0.5}], Scaled[{0., 0., 0.}], Scaled[{1., 0., 0.}], Scaled[{0.5, 1., 0.5}], Scaled[{0., 1., 0.}], Scaled[{1., 1., 0.}]}];
Wolfram Language code: Graphics3D[ℛ, PlotRange -> {{0, 10}, {0, 10}, {0, 10}}, Axes -> True]

指定相对于平常坐标的缩放位移：

Wolfram Language code: ℛ = Prism[{Scaled[{0, 0, 0.5}, {1, 0, 1}], Scaled[{0, 0, 0.5}, {0, 0, 0}], Scaled[{0, 0, 0.5}, {2, 0, 0}], Scaled[{0, 0, 0.5}, {1, 2, 1}], Scaled[{0, 0, 0.5}, {0, 2, 0}], Scaled[{0, 0, 0.5}, {2, 2, 0}]}] ;
Wolfram Language code: Graphics3D[ℛ, PlotRange -> {{0, 2}, {0, 2}, {0, 2}}, Axes -> True]

顶点可以是 Dynamic：

Wolfram Language code: DynamicModule[{x}, {Slider[Dynamic[x], {0.5, 1}], Graphics3D[Prism[{Dynamic[x{1, 0, 1}], {0, 0, 0}, Dynamic[x{2, 0, 0}], {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}]]}]

区域  (10)

嵌入维度是三棱柱所处空间的维度：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

几何维度是形体自身的维度：

Wolfram Language code: RegionDimension[ℛ]

判断是否为该区域的成员：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: {RegionMember[ℛ, {1, 1, 1}], RegionMember[ℛ, {1, 2, 3}]}

获取成为该区域成员的条件：

Wolfram Language code: RegionMember[ℛ, {x, y, z}]

体积：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: {Volume[ℛ], RegionMeasure[ℛ]}

几何中心：

Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}, Boxed -> False]

距一个点的距离：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: {RegionDistance[ℛ, {1, 0, 0}], RegionDistance[ℛ, {3, 3, 3}]}

三棱柱的等距离轮廓线：

Wolfram Language code: ContourPlot3D[Evaluate@RegionDistance[ℛ, {x, y, z}], {x, -1.5, 3}, {y, -1.5, 3.5}, {z, -1.5, 3}, Mesh -> None, Contours -> {0.25, 0.5, 1}, ContourStyle -> ColorData[94, "ColorList"], Lighting -> "Neutral", BaseStyle -> Opacity[0.5], BoxRatios -> Automatic]

距一个点的有符号距离：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: {SignedRegionDistance[ℛ, {1, 2, 3}], SignedRegionDistance[ℛ, {(1/3), (1/4), (1/5)}]}

区域中最近的点：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: {RegionNearest[ℛ, {1, 2, 3}], RegionNearest[ℛ, {(1/3), (1/4), (1/5)}]}

距外包球面最近的点：

Wolfram Language code: spherePoints[{n_, m_}, c_, r_] := Flatten[Table[c + r{Cos[k 2π / n]Sin[l π / m], Sin[k 2π / n]Sin[l π / m], Cos[l π / m]}, {k, 0., n - 1}, {l, 0., m - 1}], 1];
Wolfram Language code: pl = spherePoints[{16, 8}, RegionCentroid[ℛ], 2]; npl = Table[RegionNearest[ℛ, p], {p, pl}];
Wolfram Language code: Legended[Graphics3D[{ℛ, {Thin, Gray, Line[Transpose[{pl, npl}]]}, {Red, Point[pl]}, {PointSize[Medium], Blue, Point[npl]}}, Lighting -> "Neutral", Boxed -> False], PointLegend[{Red, Blue}, {"start", "nearest"}]]

三棱柱是有界的：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: BoundedRegionQ[ℛ]

求范围：

Wolfram Language code: r = RegionBounds[ℛ]
Wolfram Language code: Graphics3D[{{EdgeForm[White], Opacity[0.2, Yellow], Cuboid@@Transpose[r]}, ℛ}, Boxed -> False]

在三棱柱区域上积分：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: Integrate[x + y + z, {x, y, z}∈ℛ]

在三棱柱区域上最优化：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: MinValue[{x y z - x y, {x, y, z}∈ℛ}, {x, y, z}]

在三棱柱区域上解方程：

Wolfram Language code: ℛ = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: Reduce[x^2 + y^2 + z^2 == 1 && x - y - z == -1 && z^2 == x y && {x, y, z}∈ℛ, {x, y, z}]

属性和关系  (2)

可以用三个四面体的并集表示一个三棱柱：

Wolfram Language code: pts = {{1, 1, 2}, {2, 2, 2}, {0, 2, 2}, {1, 1, 0}, {2, 2, 0}, {0, 2, 0}};
Wolfram Language code: Graphics3D[Prism[pts], Boxed -> False]

四面体顶点的点索引列表：

Wolfram Language code: ti = {{6, 3, 2, 1}, {5, 6, 2, 1}, {4, 6, 5, 1}};
Wolfram Language code: Graphics3D[{Opacity@0.4, Table[Tetrahedron[pts[[i]]], {i, ti}]}, Boxed -> False]

ImplicitRegion 可以表示任意 Prism 区域：

Wolfram Language code: Subscript[ℛ, 1] = ImplicitRegion[Subscript[t, 2] ≥ 0 && Subscript[t, 1] - Subscript[t, 3] ≥ 0 && Subscript[t, 1] + Subscript[t, 3] ≤ 2 && Subscript[t, 3] ≥ 0 && Subscript[t, 2] ≤ 2, {Subscript[t, 1], Subscript[t, 2], Subscript[t, 3]}]; Subscript[ℛ, 2] = Prism[{{1, 0, 1}, {0, 0, 0}, {2, 0, 0}, {1, 2, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: RegionEqual[Subscript[ℛ, 1], Subscript[ℛ, 2]]

巧妙范例  (1)

将一个三棱柱绕轴旋转：

Wolfram Language code: ℛ = Prism[{{1, 0.5, 1}, {0, 0, 0}, {2, 0, 0}, {1, 1.5, 1}, {0, 2, 0}, {2, 2, 0}}];
Wolfram Language code: Graphics3D[{Opacity[0.3], EdgeForm[], Table[{ColorData["Rainbow"][Rescale[c, {0, 2Pi}]], GeometricTransformation[ℛ, RotationTransform[c, {0, 0, 1}, {2, 0, 0}]]}, {c, 0, 2Pi, 2Pi / 25}]}]
Wolfram Research (2014)，Prism，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Prism.html （更新于 2019 年）.

文本

Wolfram Research (2014)，Prism，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Prism.html （更新于 2019 年）.

CMS

Wolfram 语言. 2014. "Prism." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2019. https://reference.wolfram.com/language/ref/Prism.html.

APA

Wolfram 语言. (2014). Prism. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Prism.html 年

BibTeX

@misc{reference.wolfram_2026_prism, author="Wolfram Research", title="{Prism}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Prism.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_prism, organization={Wolfram Research}, title={Prism}, year={2019}, url={https://reference.wolfram.com/language/ref/Prism.html}, note=[Accessed: 11-September-2026]}