WOLFRAM

Wolfram 语言与系统参考资料中心

Cube[]

表示以原点为中心、边长为单位长度的正立方体.

Cube[l]

表示边长为 l 的立方体.

Cube[{θ,ϕ},…]

表示相对于 z 轴旋转角度 θ、相对于 y 轴旋转角度 ϕ 形成的立方体.

Cube[{x,y,z},…]

表示中心为 {x,y,z} 立方体.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
图形  
规范  
样式  
区域  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

Cube

Cube[]

表示以原点为中心、边长为单位长度的正立方体.

Cube[l]

表示边长为 l 的立方体.

Cube[{θ,ϕ},…]

表示相对于 z 轴旋转角度 θ、相对于 y 轴旋转角度 ϕ 形成的立方体.

Cube[{x,y,z},…]

表示中心为 {x,y,z} 立方体.

更多信息和选项

范例

打开所有单元 关闭所有单元

基本范例  (3)

一个立方体：

Wolfram Language code: Graphics3D[Cube[]]

不同样式的立方体：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: {Graphics3D[{Pink, ℛ}], Graphics3D[{EdgeForm[Thick], ℛ}], Graphics3D[{EdgeForm[Dashed], ℛ}], Graphics3D[{EdgeForm[Directive[Thick, Dashed, Blue]], Pink, ℛ}]}

体积和几何中心：

Wolfram Language code: ℛ = Cube[{1, 2, 3}, 2];
Wolfram Language code: Volume[ℛ]
Wolfram Language code: RegionCentroid[ℛ]

范围  (11)

图形  (8)

规范  (5)

一个立方体：

Wolfram Language code: Graphics3D[Cube[]]

单位立方体：

Wolfram Language code: Graphics3D[Cube[], PlotRange -> 1.1]

明确指定边长的单位立方体：

Wolfram Language code: Graphics3D[Cube[1], PlotRange -> 1.1]

一个边长为 2 的立方体：

Wolfram Language code: Graphics3D[Cube[2], PlotRange -> 1.1]

一个边长为 1/2、中心位于 (1/2, 1/2, 1/2) 的立方体：

Wolfram Language code: Graphics3D[Cube[{1, 1, 1} / 2, 1 / 2], PlotRange -> 1.1]

绕 轴旋转 45° 的单位立方体：

Wolfram Language code: Graphics3D[Cube[{45°, 0}], PlotRange -> 2]

绕 轴旋转 45° 的单位立方体：

Wolfram Language code: Graphics3D[Cube[{0, 45°}], PlotRange -> 2]

一个边长为 2 的立方体，绕 轴旋转 45°，再绕 轴旋转 45°：

Wolfram Language code: Graphics3D[Cube[{45°, 45°}, 2], PlotRange -> 2]

一个边长为 1、中心位于 (1/2, 1/2, 1/2) 的立方体，绕 轴旋转 45° 后，再绕 轴旋转 45°：

Wolfram Language code: Graphics3D[Cube[{1, 1, 1} / 2, {45°, 45°}, 1], PlotRange -> 2]

样式  (3)

可用 FaceForm 和 EdgeForm 来指定面和边的样式：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: Graphics3D[{EdgeForm[{Thick, Dashed, Blue}], FaceForm[{Pink, Opacity[0.7]}], ℛ}, Boxed -> False]

对面应用 Texture：

Wolfram Language code: ℛ = Cube[{0, 0, 0}, VertexTextureCoordinates -> Flatten[Table[{j / 2, i / 3}, {i, 0, 3}, {j, 0, 2}], 1]];
Wolfram Language code: Graphics3D[{Texture[[image]], ℛ}, Lighting -> "Neutral"]

为顶点设置 VertexColors：

Wolfram Language code: ℛ = Cube[{0, 0, 0}, VertexColors -> ColorData[54, "ColorList"]];
Wolfram Language code: Graphics3D[ℛ, Lighting -> "Neutral"]

区域  (3)

嵌入维度是立方体所在空间的维度：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: RegionEmbeddingDimension[ℛ]

几何维度是形体自身的维度：

Wolfram Language code: RegionDimension[ℛ]

几何中心：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: c = RegionCentroid[ℛ]
Wolfram Language code: Graphics3D[{{Opacity[0.5], LightBlue, ℛ}, {PointSize[Large], Red, Point[c]}}, Boxed -> False]

立方体是有界的：

Wolfram Language code: ℛ = Cube[];
Wolfram Language code: BoundedRegionQ[ℛ]

求它的范围：

Wolfram Language code: RegionBounds[ℛ]

巧妙范例  (2)

通过绕 轴旋转立方体副本创建多棱柱：

Wolfram Language code: Graphics3D[Table[Cube[{k Pi / 10, 0}], {k, 5}]]

将双曲面显示为沿空间对角线旋转的立方体的包络面：

Wolfram Language code: zCube = GeometricTransformation[ Cube[], RotationTransform[{{1, 1, 1}, {0, 0, 1}}] ];
Wolfram Language code: Graphics3D[Table[GeometricTransformation[zCube, RotationTransform[k Pi / 15, {0, 0, 1}]], {k, 15}], ViewPoint -> {2, 0, 0}]
Wolfram Research (2019)，Cube，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cube.html.

文本

Wolfram Research (2019)，Cube，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cube.html.

CMS

Wolfram 语言. 2019. "Cube." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Cube.html.

APA

Wolfram 语言. (2019). Cube. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Cube.html 年

BibTeX

@misc{reference.wolfram_2026_cube, author="Wolfram Research", title="{Cube}", year="2019", howpublished="\url{https://reference.wolfram.com/language/ref/Cube.html}", note=[Accessed: 12-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cube, organization={Wolfram Research}, title={Cube}, year={2019}, url={https://reference.wolfram.com/language/ref/Cube.html}, note=[Accessed: 12-September-2026]}